* ======================================================================= 
*  File:  	pooling_odds_ratios.SPS .
*  Date:  	14-Nov-2003 .
*  Author:      Bruce Weaver, weaverb@mcmaster.ca .
*  Notes:	Demonstration of how to pool odds ratios using the Cochran-
*		Mantel-Haenszel method, and using logistic regression .
* ======================================================================= .

DATA LIST LIST / sex exposed disease count (4f5.0) .
BEGIN DATA.
1 1 1 160
1 1 2 80
1 2 1 440
1 2 2 320
2 1 1 240
2 1 2 330
2 2 1 160
2 2 2 270
END DATA.

val lab 
	sex		1	'Male'
			2	'Female' /
	exposed	        1	'Yes'
			2	'No' /
	disease	        1	'Yes (case)'
			2	'No (control)' .

var lab
 sex 		'Sex'
 exposed	'Exposed'
 disease 	'Disease' .

weight by count.


* Get odds ratios for males and females separately.

CROSSTABS
  /TABLES=exposed  BY disease BY sex
  /FORMAT= AVALUE TABLES
  /STATISTIC=risk
  /CELLS= COUNT .


* Get odds ratio for Exposed x Disease table, all data pooled .

CROSSTABS
  /TABLES=exposed  BY disease
  /FORMAT= AVALUE TABLES
  /STATISTIC=risk
  /CELLS= COUNT .


* OR for Males:		1.455 (1.073, 1.972)	.
* OR for Females:	1.227 (0.949, 1.586)	.
* OR for pooled data:	0.959 (0.802, 1.147)	.


* OR from pooled data is not consistent with the ORs from
* males & females separately.  This is due to confounding 
* of Sex and Exposure (a much higher proportion of females
* were exposed to the risk factor).

* The solution to this problem is to pool the odds ratios
* rather than pooling the data.

* Odds ratios from 2x2 tables like this can be pooled
* using the Cochran-Mantel-Haenszel (CMH) method, as follows.



*=== Use CMH method to pool the odds ratios =====.

CROSSTABS
  /TABLES=exposed  BY disease BY sex
  /FORMAT= AVALUE TABLES
  /STATISTIC=CMH(1)
  /CELLS= COUNT .

* OR for Males:			1.455 (1.073, 1.972)	.
* OR for Females:		1.227 (0.949, 1.586)	.
* OR for pooled data:		0.959 (0.802, 1.147)	.
* Pooled OR (CMH Method):	1.318 (1.084, 1.604)	.

* So, pooling the odds ratios (rather than computing an odds ratio
* using pooled data) provides an estimate that is much more
* consistent with what we see in the individual strata.


*=== Use logistic regression to pool the odds ratios ====.

* We could have used logistic regression (rather than
* the CMH chi-square method) to pool the odds ratios.

LOGISTIC REGRESSION VAR=disease
  /METHOD=ENTER exposed sex
  /ENTER exposed*sex
  /CONTRAST (exposed)=Indicator(1)
  /PRINT=CI(95)
  /CRITERIA PIN(.05) POUT(.10) ITERATE(20) CUT(.5) .


* The odds ratio for EXPOSED (pooling across male
* and female) is shown in the EXP(B) column of the 
* "Variables in the Equation" box for Block 1.
* Notice that it is virtually identical to the
* pooled odds ratio we obtained earlier using the
* CMH method.

* Pooled OR (CMH Method):		1.318 (1.084, 1.604)	.
* Pooled OR (logistic regression):	1.318 (1.083, 1.603)	.


* Block 2 in the logistic regression output includes
* the EXPOSED x SEX interaction term.  Notice that 
* the p-value for this interaction term is virtually
* identical to the p-values for the two tests of
* homogeneity shown in the CMH output earlier.

* Homogeneity Test	Chi-sqr	       df  	  p		.
* Breslow-Day		0.699		1	0.403		.
* Tarone's 		0.699		1	0.403		.
* EXPOSED x SEX  	0.698		1	0.403		.



* So, the logistic regression analysis gives us all
* of the same information as the CMH method. 


*=== Which method should you use? ===== .

* In my opinion, there is not much point in using
* the Cochran-Mantel-Haenszel method these days.
* As we have just seen, logistic regression can be
* used instead, and it is a much more general and
* more flexible approach.  Specifically, one can
* control for any combination of categorical AND
* continuous confounders with logistic regression;
* but the CMH approach cannot handle continuous
* confounders.

* In its day, the CMH approach was very useful.
* But as I see it, now that personal computers and
* powerful stats packages capable of performing 
* logistic regression abound, it has become somewhat
* of an historical curiosity (much like the shortcut
* formulae for Spearman rho, phi-coefficient, etc).


* End of file.

* ======================================================================= .