<%
'
'Module:		includeGraph.asp
'Description:	One-shot graphing include
'				(hauls in expanded versions of other includes)
'Basis:			GetFileContent("includeGraphOnly.asp") & _ 
'				GetFileContent("includeArray.asp") & _
'				GetFileContent("includeMergesort.asp") & _
'				GetFileContent("includeReport.asp")
'

'
'Module:		includeGraphOnly.asp
'Description:	Generalized graphing include
'Author:		James Barbetti, 10-Nov-2000 
'Style Notes:	No subs are used.  Everything is a function.
'				Using functions makes it easier to call
'				them via the EVAL function.
'History:	
'
'	WHILE AT GMDI
'
'+	10-Nov-2000	Plotting of X/Y Scatter Graphs
'+	12-Nov-2000 Frequency histograms and plots
'+	13-Nov-2000 X and Y axes (limited date support though)
'				Additional comments explaining each function
'+   14-Nov-2000 Support for multiple-series graphing:
'				ThreeDBarPlot, quickSeriesPlot.
'				Support for line-graphs.
'				Some explanatory comments.
'				Numerous minor bug fixes.
'
'	AS A HOME PROJECT				
'
'+	07-Feb-2001 Added support for side-by-side "bar" graphs,
'				of multiple series.
'				Added support for area and stacked area
'				graphs.
'				Added support for pie graphs (single X value
'				only so far.  Later version you will be able
'				to supply additional X values).
'+	08-Feb-2001	Now renders with Netscape 4.7
'		      + Now supports rendering of tiled or static images
'				within arbitary areas, using offsetPictureAttr
'				when calculating DIV attributes (in IE anyway).
'			  + Corrected "horizontal line" bug in plotPieSlice.
'		      - Still doesn't line up tiles for Netscape.
'				Removed ThreeDBarPlot
'			  +	Draws (grey?) grid lines when drawing axes, if
'				either the graphImplyXGrid or graphImplyYGrid 
'				variables are set to true.
'			  +	See also graphGridColorExpr.
'+	09-Feb-2001 Now renders with Netscape 6
'             + Corrected bugs in pie charting drawing logic
'             + Pie charts work when there are multiple X values
'               (separate chart for each X value)
'			  + Limited support for series labeling in pie charts
'				(i) labels "inside", and (ii) labels "outside"
'				the pie slices.
'+  10-Feb-2001 You may now 
'			  + Supply strings instead of numeric values for
'				both the X and Y axes.  
'			  - However, the strings will be displayed in
'				ascending collation order, NOT in the order
'				they appeared in the input array.
'			  - This problem IS fixable (by allowing the
'				caller to supply additional columns), but I
'				haven't implemented the fix yet.
'Todo:
'
' + add: writeGridWatermark(img)
'		to draw a watermark image behind the grid.
'		problem this time is the space used up by the rendering of the legend.
' + change: formatting for legends and point values (it should be user settable)
' - change: low bar values can appear below Y axis.  Shouldn't be.
' - change: fix offset-image plotting in Netscape 4.7 and
'			6.0.  This still does not work at all.
' + add: support for multiple series columns (where one is
'		the series sort value and the other the HTML to
'		display for the series).
' + add: support for additional X and Y columns (to give
'		the text to display along the X or Y axis).
'
'Graph Settings
'	-	Note that the graphWidth,graphLeft, etc. settings
'		are for the data to be plotted.  They do not include
'		overhead for plotting axes to left and below.
'		Nor do they include overhead for plotting the series
'		names etc. below the plotting area.
'
dim graphXOrigin	'if true, force X origin to be zero
dim graphYOrigin	'if true, force Y origin to be zero
dim graphWidth		'the width of the plotting area in pixels
dim graphHeight		'the height of the plotting area in pixels
dim graphLeft		'the left of the plotting area
dim graphTop		'the top of the plotting area
dim graphXAxis		'True if X-Axis is to be displayed
dim graphYAxis		'True if Y-Axis is to be displayed

dim graphSeriesBoxWidth		'width for boxes shown for colors of series
Dim graphSeriesBoxHeight	'height for boxes shown for colors of series
							'you'd set this to the line thickness (or thereabouts)
dim graphSeriesBoxXSpace	'space to leave for series box (X pixels)
dim graphSeriesBoxYSpace	'space to leave for series box (Y pixels)


dim graphImpliedGridX		'true to automatically draw in X grid lines ---
dim graphImpliedGridY		'true to automatically draw in Y grid lines |
dim graphGridColorExpr		'expression to choose colour for grid lines
dim graphDefaultColorArray	'array of default colours for series

dim graphPieLabel			'="inside" to put in the slice, "outside" to put outside



graphTop = 50
graphHeight = 400
graphWidth = 550
graphLeft = 50

graphSeriesBoxWidth = 30
graphSeriesBoxHeight = 30
graphSeriesBoxXSpace = 40
graphSeriesBoxYSpace = 40

graphImpliedGridX  = true
graphImpliedGridY  = false
graphGridColorExpr = "iif(value=0," & chr(34) & "red" & chr(34) & "," & chr(34) & "#E0E0E0" & chr(34) & ")"

graphDefaultColorArray = Array("red","green","gold","blue","purple","orange" _
	,"lightblue","black","grey","brown" ,"yellow","pink")

graphPieLabel = "outside"

function DumpParameters(byval comment, byval parmArray)
  '
  'Description:	Display the parameters about to be passed
  '				to a function, by writing them to the 
  '				Response.
  'Explanation:	This is a diagnostic routine that I use
  '				during testing and debugging; it makes it
  '				easy to see what parameters I'm about to
  '				pass to a function call.
  'Example:		Say you have a call you consider suspect.
  '
  ' 			f = x(a,b,c,d).
  '
  '				You can dump the parameters using copy-paste,
  '				thus:
  '
  '				DumpParameters "x", Array(a,b,c,d)
  '
  dim elt
  Response.Write comment & "=("
  for each elt in parmArray
    if isArray(elt) then 
      Response.Write "Array(" & server.HTMLEncode(Join(elt, ",")) & ")"
    else
      Response.Write server.HTMLEncode(elt)
    end if
    Response.Write ","
  next
  Response.Write ")<BR>" & vbCrlf
end function

'----------------------
'BROWSER VERSION CHECKS
'----------------------
'Netscape 4.7 and earlier uses layers.
'Netscape 6 does not use layers, but is not quite the same
'as IE in some respects.  For example, if you have
'<TD Width=10 Height=10 BGCOLOR=red></TD> in IE, it will
'display the table cell.  In Netscape4.7 AND 6, you must
'put something *inside* the cell or it won't render at all.
'
dim isNetscapeKnown
dim isKnownToBeNetscape
function isNetscapeLayerBrowser()
  if not isNetscapeKnown Then
    dim userAgent
    userAgent = Request.Servervariables("HTTP_USER_AGENT")
    isKnownToBeNetscape = (instr(1,userAgent,"Mozilla")=1 and instr(1,userAgent,"MSIE")=0) _
		and (instr(1,userAgent,"Mozilla/5.0"))=0
		'This last because NS6 is more like IE
	isNetscapeKnown = true
  end if
  isNetscapeLayerBrowser = isKnownToBeNetscape
end function

dim isNetscape6Known
dim isKnownToBeNetscape6
function isNetscape6Browser()
  if not isNetscape6Known Then
    dim userAgent
    userAgent = Request.Servervariables("HTTP_USER_AGENT")
    isKnownToBeNetscape6 = (instr(1,userAgent,"Mozilla")=1 and instr(1,userAgent,"MSIE")=0) _
		and 0<(instr(1,userAgent,"Mozilla/5.0"))
		'This last because NS6 is more like IE
	isNetscape6Known = true
  end if
  isNetscape6Browser = isKnownToBeNetscape6
end function



Function setVariant(byval newValue, byref variable)
  '
  'Description:		Sets the value of a variant variable to a variant
  '					expression.
  'Explanation:		The Eval function gives you the ability to evaluate
  '					an arbitrary *expression*.  It does not give you the
  '					ability to directly call a *procedure*.  This sounds
  '					bad, but it isn't.  By putting a series of statements
  '					to execute *into* a function, you can run them via Eval.
  '					That is,
  '
  '					Eval("SetVariant(y,x)")
  '
  '					is the closest we can get to:
  '
  '					Eval("set x=y")
  '
  '					and unlike Eval("x=y"), which merely indicates whether
  '					x and y are the same, it will *make* them the same
  '
  if isobject(newvalue) Then
    set variable = newValue
    set setVariant = newValue
  else
    variable = newValue
    setVariant = newValue
  end if
End Function

Function iif(byval testThis, byval ifTrue, byval ifFalse)
  '
  'Description:		Immediate If
  'Parameters:		testThis	-	Either true or false
  '					ifTrue		-	The value to return if testThis is true
  '					ifFalse		-	The value to return if testThis is false
  '									(or Null, or a non-boolean).
  'Explanation:		Equivalent to the IIF of Access and Excel
  '
  if testThis Then
    iif = ifTrue
  else
    iif = ifFalse
  end if
end function

Function modifyColumns(byref columnIndexArray, byref formulaArray _
	, byref scratch, byref dataArray) 
  '
  'Description:	Carry out operations on some or all of the columns
  '				of an array.
  'Examples:	(1) Convert column values to proportion of total (for column 1):
  '		
  '				sumofCol1 = modifyColumns(Array(1) _
  '					, Array("setVariant(scratch+iff(isnull(value),value,0),scratch)*0+value") _
  '					, 0, dataArray)
  '				modifyColumns Array(1),"value/" + cstr(sumOfCol1),dataArray
  '
  '				(2) Rescale column values based on min->max range...
  '					To 0 through 1 (see rescaleColumnsOfArray):
  '
  '				minmax = modifyColumns(Array(1) _
  '					, Array("SetVariant(iif(value<scratch(0),value,scratch(0)),scratch(0))*0" _
  '					+ "+SetVariant(iif(scratch(1)<value,value,scratch(1)),scratch(1))*0" _
  '					+ "+value"), Array(0,0), dataArray)
  '				modifyColumns Array(1),"(value-scratch(0))/scratch(1)", minmax, dataArray
  '					
  '
  'Parameters:	columnIndexArray - array of columns which are to be processed
  '				formulaArray     - array of formulae for modifying the values in
  '								   the columns (same # of elements as columnIndexArray)
  '				scratch			 - scratch parameter that can be used in calculations
  '								   (see the rescale example above).
  '			    dataArray		 - array of rows (each an array of columns) 
  '								   for which the columns are to be modified.
  '
  Dim rowIndex		'
  Dim colIndexIndex	'
  Dim columnIndex	'
  Dim value			'
  
  If Not isempty(dataArray) Then
    For rowIndex = lbound(dataArray) to ubound(dataArray)
      For colIndexIndex = lbound(columnIndexArray) To ubound(columnIndexArray)
        columnIndex = columnIndexArray(colIndexIndex)
        value = dataArray(rowIndex)(columnIndex)
        value = Eval(formulaArray(colIndexIndex))
        dataArray(rowIndex)(columnIndex) = value
      Next
    Next
  End If
  modifyColumns = scratch
end function

sub AdjustMinMax(byval index, byref dataArray, byref minmax)
  '
  'Description:	Adjusts a variable containing the minimum
  '				and maximum values to be plotted on an axis,
  '				according to the values it finds in the
  '				specified column of the input array.
  'Parameters:	index - the column index
  '				dataArray - the data array
  '					(passed by reference, NOT because it 
  '					is modified, but for performance reasons)
  '				minMax - on entry, either empty or a 
  '					2-element array: Array(Minimum,Maximum).
  '					on exit, a 2-element array giving the
  '					minimum and maximum values to be plotted.
  'Notes:		Strings are treated differently!  if the
  '				first row of the input array contains a string
  '				in the specified column, then the number of
  '				distinct strings is counted, and the range
  '				of values in the column is considered to
  '				be (0,differentStringCount-1).
  '
  
  if not isempty(dataArray) Then
    if isempty(minMax) then
      minMax = Array(dataArray(0)(index), dataArray(0)(index))
    end if
    if typename(dataArray(lbound(dataArray))(index)) = "String" Then
      minMax = Array(0, ubound(differentValuesInColumn(dataArray,index)) )
      'Cheat for strings!
    else
	  minmax = modifyColumns(Array(index) _
	    , Array("SetVariant(iif(value<scratch(0),value,scratch(0)),scratch(0))*0" _
	    + "+SetVariant(iif(scratch(1)<value,value,scratch(1)),scratch(1))*0" _
	    + "+value") _
	    , minmax, dataArray)
	end if
  end if
end sub

sub mapStringColumnToLongs(byval index, byref dataArray)
  '
  'Description:	Converts the values in a string column into
  '				numbers.  All of the values found in the
  '				column are ordered, and then each string
  '				is replaced by a number indicating its 
  '				order.
  'Example:		After
  '
  '				x = Array(array("Dog"),Array("Cat"),Array("Dog"))
  '				mapStringColumnToLongs 0, x
  '
  '				x will be Array(array(1),Array(0),Array(1)).			 
  '
  'Notes:		This routine is used when displaying strings
  '				on the X and Y axes.
  '
  dim i	         'index into array
  dim j          'equivalence class # for current string
  dim lastString 'last string found
  
  MergeSortEntireArray dataArray, Array(index)
  j = 0
  for i = lbound(dataArray) to ubound(dataArray)
    if lastString <> dataArray(i)(index) then
      if lbound(dataArray)<i then j=j+1
      lastString = dataArray(i)(index)
    end if
    dataArray(i)(index) = j
  next
end sub

sub rescaleColumnsOfArray(byref columnIndexArray, byval lowArray, byval highArray _
	, byref dataArray, byref valueRanges)
  '
  'Description:	Scales the values in an array against any number of axes.
  'Example:		See the quickSeriesPlot routine.
  '				Say, you have an array with x,y,z coordinates in columns
  '				0,1 and 2, and you want to scale between (x1,x2), (y1,y2),
  '				(z1,z2) [note: for negative Y scaling, supply y2<y1.  This
  '				is what happens in quickSeriesPlot()]...
  '				After a call to
  '
  '				rescaleColumnsOfArray(Array(0,1,2),Array(x1,y1,z1),Array(x2,y2,z2) _
  '					, dataArray, ranges
  '
  '				the three columns will each have been rescaled (values in x
  '				to fit between x1 and x2, values in y to fit between y1 and y2),
  '				and ranges(0)(0)=minimum value of x
  '					ranges(0)(1)=maximum value of x
  '					ranges(1)(0)=minimum value of y, and so on.
  'Parameters:	columnIndexArray	- input. Array.  Indices of columns to rescale
  '				lowArray			- input array, lower bounds for each column 
  '									  to rescale
  '				highArray			- input array, upper bounds for each column
  '				dataArray			- input/output (columns indicated will be
  '									  rescaled)
  '				valueRanges			- output array.  Will be populated with
  '								      an array of (min,max) pairs as shown in
  '									  the example above.
  '									  CAN ALSO SUPPLY KNOWN RANGES HERE
  'Notes:		Strings are treated differently.  The
  '				mapStringColumnToLongs function is used.
  '			
  dim arrayIndex	'index into the array of indices of
					'columns to scale
  Dim columnIndex	'the index of the current column to scale
  Dim low			'the low plotting value for the column
  Dim high			'the high plotting value for the column
  dim minmax		'a range Array(lowActual, highActual)
					'of the actual values found in the column
  dim offset		'The offset to be used in the rescaling formula
  dim scaling		'The scaling factor to be used
  dim formula		'The rescaling formula, as a VB expression
  
  '
  'Notes:	the idea is as follows; we find the minima and
  '			maxima for each of the columns.
  '			Then we determine, given the actual minima and
  '			maxima, and the (low,high) plotting values for
  '			the column, a formula that will determine 
  '			the plotting coordinate for each value in the
  '			current column.
  '			For example, say we have Y values 0,4,10
  '			and we must plot between y of 450 and 50.
  '			we get
  '				scaling: -40
  '				offset:  450
  '				formula: value*-40 + offset
  '			which
  '			when applied to the array, replaces the Y
  '			values of (0,4,10) with their equivalent
  '			screen coordinates (450,290,50).
  '
  
  If Isempty(valueRanges) Then Redim ValueRanges(ubound(columnIndexArray))
  For arrayIndex = lbound(columnIndexArray) to ubound(columnIndexArray)
    columnIndex = columnIndexArray(arrayIndex)
    'Response.Write "ZX: Rescaling " & columnIndex & "<BR>" & vbCrlf
    low = lowArray(arrayIndex)
    high = highArray(arrayIndex) 
    If IsEmpty(valueRanges(arrayIndex)) Then       
      minMax = empty
      adjustMinMax columnIndex, dataArray, minmax
    else
      minmax = valueRanges(arrayIndex)
    end if    
    if (minmax(1)<>minmax(0)) Then
      scaling = (high-low) / (minmax(1) - minmax(0)) 
    else
      scaling = 1
    end if
    if typename(dataArray(lbound(dataArray))(columnIndex)) = "String" Then
      'Response.Write "ZX: Mapping strings in column " & Columnindex & "<BR>" & vbCrlf
      mapStringColumnToLongs columnIndex, dataArray
      'Response.Write "ZX: Strings mapped for column " & Columnindex & "<BR>" & vbCrlf
      'DumpArrayOfArraysAsTable dataArray,2,false 'ZX
    end if
    offset = (low - minmax(0)*scaling)  'difference between desired and actual minima    
    if typename(minmax(0))="Date" then
      offset = cdbl(offset)
      formula = "cdbl(value)*" & cstr(scaling) & "+" & cstr(offset)
    else
      formula = "value*" & cstr(scaling) & "+" & cstr(offset)
    End If
    modifyColumns Array(columnIndex), Array(formula), empty , dataArray
    ValueRanges(arrayIndex) = minmax
  Next
end sub

sub cumulativeFrequencyForArray(byval countColumn _
	, byval valueColumn, byval isTotalShown, byref dataarray)
	'
	'Description:	
	'
	mergeSortEntireArray dataArray, array(valueColumn)		'sort by the thing being sorted on
	if isTotalShown Then
	   modifyColumns  array(valueColumn), Array("setVariant(value+scratch,scratch)"), 0, dataArray	
	End If
	modifyColumns array(countColumn), Array("setVariant(value+scratch,scratch)"), 0, dataArray
end sub

sub prepareArrayForFrequencyHistogram(byval countColumnIndex _
	, byval valueColumnIndex, byval isTotalshown, byval barCount, byref dataArray)
	'
	'Description:	Prepares for a graph where the population is the X axis
	'Parameters:	countColumnIndex - the index of the column which contains
	'					the count of the number of records (for each row)
	'				valueColumnIndex - the index of the column which contains
	'					the values to be plotted on the Y axis.
	'				isTotalShown - indicates if the accumulated *total* of
	'					the values in the [valueColumnIndex] is to be shown.
	'				    If true, yes.  If false, individual values are to be shown.
	'				barCount - number of bars to put in the histogram
	'					(e.g. for twenty bars, pass 20).
	'				dataArray - input/output : on entry, the data array to be
	'					prepared.  On exit, a "condensed" version with barCount
	'					elements.
	'
	if not isempty(dataArray) then
	  cumulativeFrequencyForArray countColumnIndex, valueColumnIndex, isTotalShown, dataArray
	  If ubound(dataArray) + 1 <barCount Then
	    'Too few data elements for the histogram desired. We'll have to
	    'interpolate.  I have NOT written code for this yet. -JB
	    'Should raise an error and drop out.
	  else
	    Dim barStep
	    Dim barStart
	    Dim tryIndex
	    Dim outIndex
	    barStep = Int((ubound(dataArray)+1)/(barCount-1))
	    barStart = ubound(dataArray) - int((ubound(dataArray)+1)/barStep) * barStep
	    For tryIndex = barStart to ubound(dataArray) step barStep
	      if outIndex<tryIndex Then
	        dataArray(outIndex) = dataArray(tryIndex)
	      end if
	      outIndex = outIndex + 1
	    Next
	    Redim preserve dataArray(outIndex-1)
	  end If
	end if
end sub

sub prepareArrayForSeriesFrequencyPlot( _
    byval seriesColumnIndex, byval countColumnIndex _
	, byval valueColumnIndex, byval pointCount _
	, byref dataArray)
	Dim val
	Dim seriesData
	Dim row
	Dim result
	mergesortEntireArray dataArray, Array(seriesColumnIndex, valueColumnIndex)
	For each val in differentValuesInColumn(dataArray, seriesColumnIndex)
	  seriesData = filteredArray((dataarray), array(seriesColumnIndex), array(val))	  
	  prepareArrayForFrequencyPlot countColumnIndex, valueColumnIndex _
		, pointCount, seriesData
	  for each row in seriesData
	    addElementToArray row, result	    
	  next
	Next
	dataArray = result
end sub

sub prepareArrayForFrequencyPlot(byval countColumnIndex _
	, byval valueColumnIndex, byval pointCount _
	, byref dataArray)
	'
	'Description:	Prepares for a graph where the population is the Y axis
	'Example:		Plotting games (Y axis) versus score range (X axis).	
	'				See the "score by date" report in cms/showReport.asp.
	'Parameters:	countColumnIndex	- column containing counts of values
	'				valueColumnIndex	- column containing values to be shown
	'									  in ranges along the X axis
	'				pointCount			- the number of points (or bars)
	'									  to display along the X axis
	'				dataArray			- input: values to plot
	'									  output: pointCount elements.
	'									  Column (valueColumnIndex) will
	'									  have upper bounds of each of the
	'									  value ranges.
	'									  Column (countColumnIndex) will
	'									  have the # of values that fell
	'									  within that range.
	'
	if not isempty(dataArray) then
	  mergeSortEntireArray dataArray, array(valueColumnIndex)
	  '
	  'Determine minimum and maximum values
	  '
	  Dim minMax, minValue, maxValue
	  Dim threshold
	  Dim inputIndex, outputIndex
	  minmax = modifyColumns(Array(ValuecolumnIndex) _
        , Array("SetVariant(iif(value>=scratch(0),scratch(0),value),scratch(0))*0" _
        + "+SetVariant(iif(scratch(1)>=value,scratch(1),value),scratch(1))*0" _
        + "+value") _
        , Array(dataArray(0)(valuecolumnIndex),dataArray(0)(valuecolumnIndex)), dataArray)
	  minValue = minmax(0)
	  maxValue = minmax(1)    
	  '
	  'Collapse the array, so that each output row will now have
	  ' thisRow(valueColumnIndex) = upper threshold for the range
	  ' thisRow(countColumnIndex) = sum of the counts for the  rows where the value 
	  '								fell in the range indicated by the threshold
	  '							    (and the threshold of the previous output row)
	  '
	  outputIndex = 0
	  threshold = minValue
	  for inputIndex = 0 to ubound(dataArray)
	    if inputIndex=0 Or threshold<dataArray(inputIndex)(valueColumnIndex) Then
	      if 0<inputIndex Then outputIndex = outputIndex + 1
	      dataArray(outputIndex) = dataArray(inputIndex)
	      dataArray(outputIndex)(countColumnIndex) = dataArray(inputIndex)(countColumnIndex)
	      dataArray(outputIndex)(valueColumnIndex) = threshold
	      threshold = threshold + (maxValue - minValue) / (pointCount - 1)
	    else
	      dataArray(outputIndex)(countColumnIndex) = _
	        dataArray(outputIndex)(countColumnIndex) + dataArray(inputIndex)(countColumnIndex)
	    end if
	  next
	  Redim preserve dataArray(outputIndex)
	end if
end sub

function filteredArray(byref filterMe, byref filterColumnArray, byref filterValueArray)
  '
  'Description:	Filter out records that do not have specific values in specific
  '				columns.
  'Parameters:	filterMe		  - input/ouput - the array to filter
  '				filterColumnArray - input - array of indices of columns to check
  '				filterValueArray  - input - array of values that must be found in 
  '									each of those columns.
  '				*ALL* the columns must match.
  'Example:		filteredArray(dataArray,Array(0),Array("James"))
  '				discard all rows of the array where column 0 is not "James".
  'Notes:		This routine can only filter on *equality*.  You can't
  '				filter on an inequality (e.g. return only rows with 
  '				non-zero scores, or return only rows with attempt number > 2).
  '				It'd be good if there were a routine that could filter
  '				based *on an expression criterion*.  But there isn't.
  '
  Dim result
  Dim rowIndex
  Dim colIndex
  Dim isRowIncluded
  result = Empty
  If not isempty(filterMe) Then
    for rowIndex = lbound(filterMe) to ubound(filterMe)
      isRowIncluded = True
      For colIndex = lbound(filterColumnArray) to ubound(filterColumnArray)
        If CompareVariants(filterMe(rowIndex)(filterColumnArray(colIndex)) _
		  , filterValueArray(colIndex)) <> 0 Then
		  isRowIncluded = False
		  Exit For
		End If
      next
      If isRowIncluded Then AddElementToArray filterMe(rowIndex), result
    next
  End If
  filteredArray = result
end function

function min(a,b)
  if a<b then min=a else min=b
end function

function max(a,b)
  if a<b then max=b else max=a
end function

function plotCumulativeFrequencyGraph(byval valueColIndex _
	, byval pixelWidth, byval pixelHeight _
	, byval barAttributeExpr, byval barCaptionExpr, byval dataArray)
	'
	'Description:	Plots a bar graph (the name is a little misleading
	'				and should be changed; it need not be showing 
	'				cumulative frequencies at all).
	'Notes:			Unlike the bulk of the routines in this module this
	'				one works by building a <TABLE> in place.
	'				That's why you don't give (left,top) position and
	'				and positioning ("absolute" or "relative") parameter.
	'				To position the graphs drawn by this routine, use...
	'
	'				plotPositionStart left,top,positioning
	'				  plotCumulativeFrequencyGraph, v,width,height, ...
	'				plotPositionEnd
	'
	'Example:		"score by population" subreport of
	'				"score distribution by round and attempt" report
	'				in cms/showreport.asp.
	'		
	'Parameters:	valueColIndex	  - index of column containing values
	'				pixelWidth		  - width of the graphing region
	'				pixelHeight		  - height of the graphing region
	'				barAttributeExpr  -
	'				barCaptionExpr	  -
	'				dataArray		  -	data points to plot
	'
	Dim barCount 
	Dim bar
	Dim thisRow
	if barAttributeExpr = "" Then
	  barAttributeExpr = """bgcolor=red"""
	end if
	if barCaptionexpr = "" Then
	  barCaptionExpr = "cstr(int((bar + 1)/barCount*10000+.5)/100) & ""%"""
	end if
	rescaleColumnsOfArray Array(valueColIndex), Array(0), Array(pixelHeight), dataArray
	If not isempty(dataArray) Then
	  Response.Write "<TABLE border=0 cellspacing=0 cellpadding=0 width=" _
		& cstr(pixelWidth) & " height=" & cstr(pixelHeight) & "><TR>" & vbCrlf
	  barCount = ubound(dataArray) + 1	 
	  For bar = 0 to ubound(dataArray)
	    thisRow = dataArray(bar)
		Response.Write "  <TD width=" & cstr(int(pixelWidth/barCount)) & ">"
		Response.Write "<TABLE height=" & pixelHeight _
			& " width=" & cstr(int(pixelWidth/barCount)) & ">" & vbCrlf
		if thisRow(valueColIndex)<pixelHeight Then
		  Response.Write "<TR><TD></TD></TR>" 'Empty space above bar
		end if
		Response.Write "<TR><TD " & eval(barAttributeExpr) & " height=" _
		  & max(thisRow(valueColIndex),1) & "></TD></TR></TABLE><TD>" & vbCrlf
	  Next
	  Response.Write "</TR></TABLE>" & vbCrlf
	  '
	  'Captions at bottom
	  '	  
	  if barCount<31 Then
	    Dim stagger
	    Dim modulo
		Response.Write "<TABLE border=0 cellspacing=0 cellpadding=0 width=" & cstr(pixelWidth) & "><TR>" & vbCrlf
		stagger = int((barCount+9) / 10)
		for modulo = 0 to stagger-1
		  if 0<modulo and 1<stagger then 
		    Response.Write "  <TD colspan=" & modulo & " width=" _
				& cstr(modulo*int(PixelWidth/barCount)) & ">&nbsp;</TD>" 
		  end if
		  For bar = 0 to ubound(dataArray)
		    if (stagger=1) or (bar mod stagger)=modulo then
	          Response.Write "  <TD align=left colspan=" & stagger & " width=" & cstr(stagger*int(PixelWidth/barCount)) & ">"
	          Response.Write eval(barCaptionExpr)
	          Response.Write "</TD>" & vbCrlf
	        end if
	      next
	      Response.Write "</TR>" & vbCrlf
	    next
	    Response.Write "</TABLE>" & vbCrlf
	  end if
	End If
end function

function plotXYScatterSeries(byval xIndex, byval yIndex _
	, byref dataArray, byval pointExpr, byval offsetXexpr, byval offsetYexpr _
	, byval positioning, byval layerExpr)
  '
  'Description:	Plots a series in an X,Y scatter graph
  'Note:		Plots points, does *not* draw lines connecting the points.
  '				The x and y coordinates must *already* be scaled to the drawing
  '				region.
  'Parameters:	xIndex		- The index of the column containing the X values
  '				yIndex		- The index of the column containing the Y values
  '				dataArray	- The data array
  '				pointExpr	- An expression that will return the HTML to display
  '							  for each data point (this can be used to set an <A>
  '							  with TITLE and HREF linking information, for example).
  '				offsetXExpr	- Expression to use to calculate the offset between
  '							  the top left corner of the HTML for the data point
  '							  and the centre of the HTML for the data point (X).
  '							  If "" is supplied, default is "5".
  '				offsetYExpr	- As for offsetXExpr.
  '				positioning	- "absolute" or "relative" - how to position the graph
  '
  Dim rowIndex
  Dim x
  Dim y
  Dim thisRow 
  Dim layerAttr
   
  if positioning="" then positioning = "absolute"
  if cstr(pointExpr) = "" Then
    pointExpr = """X"""
  end if
  If cstr(offsetXexpr) = "" then offsetXexpr = "5"
  If cstr(offsetYexpr) = "" then offsetYexpr = "5"
  
  If not isempty(dataArray) Then
    for rowIndex = lbound(dataArray) to ubound(dataArray)
      x = dataArray(rowIndex)(xIndex) - Eval(offsetXexpr)
      y = dataArray(rowIndex)(yIndex) - Eval(offsetYexpr)
      thisrow = dataArray(rowIndex)
      if (not isnull(x)) and (not isnull(y)) Then
        if ""<layerExpr then layerAttr = eval(layerExpr)
        plotPositionStart x,y, positioning, layerAttr
		Response.Write Eval(pointExpr)
		plotPositionEnd positioning
      end If
    next 
  End If
end function

function plotBarseries(byval xIndexArray, byval yIndexArray _
	, byref dataArray, byval linkExpr, byval colorExpr _
	, byval yBaseline, byval positioning, byval forcedBarWidth _
	, byval layerExpr, byref oldDataArray)
  '
  'Description:	Plot a series of X,Y points as bars.
  '				The data points are already scaled
  'Parameters:	xIndex      - Index of column containing X values
  '				yIndex      - Index of column containing Y values
  '				dataArray   - The data to graph
  '				linkExpr	- Expression to evaluate to determine
  '							  link for each bar.  Note, this is
  '							  *later* URL encoded, so you need not
  '							  URL encode it.
  '				colorExpr   - The color to shade the tables
  '				yBaseLine   - The "bar baseline" - the bottom for
  '							  each of the bars.  Note that this assumes
  '							  you are *not* using "stacked" bars.
  '							  This is the y-coordinate from which each bar
  '							  grows "up" or "down".
  '				positioning - "relative" or "absolute". Relative
  '							  isn't reliable in IE.  Use absolute.
  '							
  'Notes:	(1)	Bar width is imputed from the minimum non-zero 
  '				difference between X values in the data set.
  '			(2) the yBaseLine parameter should really be an expression
  '				to evaluate.  Then you could, say, plot high and low values
  '				for things like this:
  '
  '				plotBarSeries Array(0),Array(1),dataArray,"","""red""","thisRow(2)"
  '
  '				to plot data where the columns are:
  '				time/stock=0, high=1, low=2 (or low=1, high=2).
  '
    
  dim rowIndex
  dim thisRow
  dim floatingBar
  dim x, y			'coordinates of top-left corner of block to plot
  dim x2			'coordinate of right-hand corner of block
  dim layerAttr
  dim xIndex
  dim yIndex
  dim hIndex
  dim isGannt
  dim temp
  
  xIndex = xIndexArray(0)
  yIndex = yIndexArray(0)
  if 0 < ubound(xIndexArray) then hIndex = xIndexArray(1)
  
  floatingBar = 0<ubound(yIndexArray) 
  isgannt = 0<ubound(xIndexArray)
  
  if not isempty(dataArray) Then
    dim jumpX
    dim jumpY
	if isempty(forcedBarWidth) Then
      jumpX = getMinimumDifferenceForColumn(dataArray, xIndex)	'bar width
    else
      jumpX = forcedBarWidth
    end if
    if jumpX>100 then jumpX = jumpX * .9
    
    if not floatingBar Then
      jumpY = getMinimumDifferenceForColumn(oldDataArray, yIndex)	'bar height
		'problem.  Our series might well all have the same y-value.
		'We really need the minimum difference *before* the extraction 
		'of the current data
      if jumpY>100 then jumpY = jumpY * .9
    end If
    For rowIndex = lbound(dataArray) To ubound(dataArray)
      dim onclick
      thisRow = dataArray(rowIndex)
      if isGannt Then
        x = thisRow(xIndex)
        x2 = thisRow(hIndex)
        if x2<x then temp=x:x=x2:x2=temp
        y = thisRow(yIndex) 'Todo: support 2-y-indexes passed
        if ""<linkExpr then onclick = eval(linkExpr)
        if ""<layerExpr then layerAttr = eval(layerExpr)
        plotBlock Array(x,y-jumpY/2-1) _
          , Array(x2,y+jumpY/2+1) _
		  , positioning, eval(colorExpr), onclick , "", layerAttr          
      elseif floatingBar then
        x = thisRow(xIndex)-jumpX/2-1
        y = thisRow(yIndex)
        if ""<linkExpr then
          onclick = eval(linkExpr)
        end if
        if ""<layerExpr then layerAttr = eval(layerExpr)
        plotBlock Array(thisRow(xIndex)-jumpX/2-1,thisRow(yIndexArray(0))) _
          , Array(thisRow(xIndex)+jumpX/2+1,thisRow(yIndexArray(1))) _
		  , positioning, eval(colorExpr), onclick , "", layerAttr  
      else
        x = thisRow(xIndex)-jumpX/2-1
        y = thisRow(yIndex)
        if ""<linkExpr then
          onclick = eval(linkExpr)
        end if
        if ""<layerExpr then layerAttr = eval(layerExpr)

        plotBlock Array(thisRow(xIndex)-jumpX/2-1,thisRow(yIndex)) _
          , Array(thisRow(xIndex)+jumpX/2+1,yBaseline) _
		  , positioning, eval(colorExpr), onclick , "" , layerAttr
	  end if
    next
  end if
end function

function plotX1X2Y1Y2Series(byval x1Index, byval x2Index, byval y1Index _
	, byval y2Index, byref dataArray, byval colorExpr _
	, byval positioning, byval attrExpr, byval layerAttr)
  '
  'Description:	Plots a series of blocks or boxes in an X,Y graph.
  'Note:		This is the fundamental routine used for graphing
  '				gannt and stacked bar charts.
  'Parameters:	x1Index    - index of column containing "left"
  '							 coordinate for each block
  '				x2Index    - index for "right" coordinate
  '				y1Index    - index for "top" coordinate
  '				y2Index    - index for "bottom" coordinate
  '				dataArray  - the array containing the data
  '							 to be plotted for this series
  '				colorXExpr - an expression to be evaluated to
  '							 get the colour for each box
  '				positioning- "absolute" or "relative"
  '				attrExpr   - expression to apply to the
  '							 <TABLE> tag for each block.
  '				layerExpr  - for Netscape plotting, an expression
  '							 to put in the <LAYER> tags.
  '
  dim rowindex, x1, x2, y1, y2, thisRow
  if colorExpr="" then colorExpr = chr(34) & "red" & chr(34)
  if positioning="" then positioning = "absolute"
  If not isempty(dataArray) Then
    for rowIndex = lbound(dataArray) to ubound(dataArray)
      thisRow = dataArray(rowIndex)
      x1 = thisRow(x1Index) 
      y1 = thisRow(y1Index) 
      x2 = thisRow(x2Index) 
      y2 = thisRow(y2Index) 
	  plotBlock Array(x1,y1), Array(x2,y2), positioning, Eval(colorExpr) _
		, eval(attrExpr), "", layerAttr
    next
  end if
end function

function plotStackedArea(byval leftXTB, byval rightXTB _
	, byval positioning, byval colorExpr, byval attrExpr _
	, byval layerExpr, byref thisRow)
	'
	'Description: Plot a stacked area segment using as few TABLE 
	'			  elements as possible.
	'Note:		  This is used for plotting stacked area graphs.
	'			  See the XTBAreaSeries routine (which supplies it
	'			  with the area segments to draw), and also the
	'			  quickSeriesPlot() and stackDataArray() functions.
	'
	dim x1, t1, b1, x2, t2, b2, temp
	dim xr,x,y,t,b
	Dim x0,t0,b0
	dim layerAttr
	
	layerAttr=""
	if rightXTB(0)<leftXTB(0) Then temp=rightXTB: rightXTB=leftXTB: leftXTB=temp
	x1 = leftXTB(0): t1=leftXTB(1): b1=leftXTB(2)
	x2 = rightXTB(0): t2=rightXTB(1): b2=rightXTB(2)
	t0 = int(t1+.5): b0=int(b1+.5): x0=x1
	if x1<>x2 then
	  for xr = int(x1 + 1) to x2 + 1 step sgn(x2-x1)
	    t = int((xr-x1)/(x2-x1) * (t2-t1) + t1 + .5)
	    b = int((xr-x1)/(x2-x1) * (b2-b1) + b1 + .5)
	    if t<> t0 or x2<xr then	      
	      x=x0: y=t0: if b0<y then y = b0	      
	      if ""<layerExpr then layerAttr = eval(layerExpr)
	      plotBlock   Array(x0-1,t0), Array(xr+1,b0), positioning, eval(colorExpr) _
			, eval(attrExpr), "", layerAttr
		  x0 = xr-1: t0 = t: b0 = b
	    end if
	  next
	end if
end function

function plotXTBAreaSeries(byval xIndex, byval tIndex, byval bIndex _
	, byval dataArray, byval colorExpr _
	, byval positioning, byval attrExpr, byval layerAttr)
  '
  'Description:	Given a series of (X,Y1,Y2) triplets, render them as
  '				a stacked area graph.  For each adjacent pair of
  '				elements [a,b], plot the area defined by the vertices
  '				(a.X, a.Y1), (a.X, a.Y2), (b.X, b.Y2) and (b.X, b.Y1)
  'Note:		This routine is used for drawing stacked area charts.
  '				
  dim rowIndex, thisRow, x1, x2, t1, b1, t2, b2, temp
  if colorExpr="" then colorExpr = chr(34) & "red" & chr(34)
  if positioning="" then positioning = "absolute"
  if attrExpr="" then attrExpr = chr(34) & chr(34)
  If not isempty(dataArray) Then
    for rowIndex = lbound(dataArray) to ubound(dataArray)
      thisRow = dataArray(rowIndex)
      x2 = thisRow(xIndex) 
      t2 = thisRow(tIndex)
      b2 = thisRow(bIndex)
      if b2<t2 Then temp=b2: b2=t2: t2=temp
      if lbound(dataArray)<rowIndex Then
	    plotStackedArea Array(x1, t1,b1), Array(x2,t2,b2), positioning _
			, colorExpr, attrExpr, layerAttr, thisRow
	  end if
      x1 = x2
	  t1 = t2
	  b1 = b2
    next
  end if  
end function

function addEmptyElementsToFlatArray(byval colCount, byval atIndex, byref thisArray)
  '
  'Description: Add elements to a flat array, preserving the
  '				elements already there.
  'Parameters:	colCount - number of parameters to add
  '				atIndex  - the index at which to add them
  '					(supply ubound(thisArray)+1 to add at end)
  '				thisArray - the array to modify
  'Notes:		This routine is used when adding 
  '				additional calculated columns to an array
  '				of arrays.
  '				For example, when displaying a stacked bar or
  '				stacked area graph, we derive t (top) and b
  '				(bottom) values from the y value for each
  '				row, where b is the sum of the y values found
  '				for the current x, and t is b+current y.
  '
  if isEmpty(thisArray) Then 
    redim thisArray(colCount-1)
    exit function
  else
    redim preserve thisArray(ubound(thisArray) + colCount)
  end if
  dim shuffle
  for shuffle = ubound(thisArray) to atIndex+colCount step -1
    if isobject(thisArray(shuffle - colCount)) then
	  set thisArray(shuffle) = thisArray(shuffle - colCount)
	else
	  thisArray(shuffle) = thisArray(shuffle - colCount)
	end if
  next
  dim clearIndex
  for clearIndex = atIndex to atIndex+colCount - 1
    thisArray(clearIndex) = empty
  next  
end function

function AddEmptyColumnsToArray(byval colCount, byval atIndex, byref dataArray)
  '
  'Description: Add elements to a each row of an array of
  '				arrays, preserving the elements already there.
  'Parameters:	colCount - number of columns to add
  '				atIndex  - the index at which to add them
  '					(supply ubound(thisArray(0))+1 to add at end)
  '				thisArray - the array to modify
  'Notes:		See also AddEmptyElementsToFlatArray and
  '				StackDataArray.
  'Example:		x = Array(array(1,2),array(3,4))
  '				AddEmptyColumnsToArray 1,2,x
  '				'x = Array(array(1,2,Empty),array(3,4,Empty))
  '				AddEmptyColumnsToArray 2,0,x
  '				'x = Array(array(Empty,empty,1,2,Empty) _
  '				'      , Array(Empty,Empty,3,4,Empty))
  dim i
  if not isEmpty(dataArray) Then
    for i = lbound(dataArray) to ubound(dataArray)
      AddEmptyElementsToFlatArray colCount, atIndex, dataArray(i)
    next
  end if
end function

function stackDataArray(byval xIndex, byval yIndex _
	, byref dataArray, byref seriesIndex, byref tIndex, byref bIndex)
	'
	'Description: Converts independent series data into "stacked" data
	'             suitable for plotting.
	'Algorithm:   Given a series of (S,X,Y) triplets, where S identifies
	'			  the series and X and Y are plot coordinates, sort
	'			  by X and S, and for each X, replace Y with Y1 and Y2
	'			  where Y1 is the sum of preceding values with the same
	'			  X, and Y2 is Y1+Y.
	'Assumptions: It is assumed that there are no duplicate (S,X) pairs.
	'			  It is NOT assumed that for each X each value of
	'			  S is found.  However, plotting routines called later
	'			  (when drawing stacked *area* graphs, at least) DO
	'			  make this assumption and will not render properly if
	'			  some values of X are missing for some values of S.
	'Note:		  Supply seriesIndex of NULL if all series are equivalent
	'
	dim i		'index into data array
	dim lastX	'X found for element most recently examined
	dim sumY	'sum of values found for previous S with same X
	dim newCols	'new columns required (0,1, or 2)
	dim firstRow'first row of the data array (after sorting)
	
	newCols = 0
	if not isempty(dataArray) Then
	  if not (isNull(seriesIndex)) then
	    mergeSortEntireArray  dataArray, array(xIndex, seriesIndex)
	  else
	    mergeSortEntireArray  dataArray, array(xIndex)
	  end if
	  firstRow = dataArray(lbound(dataArray))
	  lastX = dataArray(lbound(dataArray))(xIndex) 
	  if typename(lastX)<>"String" Then lastX =lastX-1 else lastX ="X" & lastX
	  if isEmpty(tIndex) then newCols = newCols+1: tIndex = ubound(firstRow)+newCols
	  if isEmpty(bIndex) then newCols = newCols+1:bIndex = ubound(firstRow)+newCols
	  if 0 < newCols Then
	    AddEmptyColumnsToArray newCols, ubound(firstRow)+1, dataArray
	  End If
	  sumY = 0
	  for i = lbound(dataArray) to ubound(dataArray)
	    if lastX<>dataArray(i)(xIndex) or isNull(seriesIndex) then sumY=0
	    dataArray(i)(bIndex) = sumY
	    sumY = sumY + dataArray(i)(yIndex)
	    dataArray(i)(tIndex) = sumY
	    lastX=dataArray(i)(xIndex)
	  next	  
	end if	
	if not (isNull(seriesIndex)) then 
	  mergeSortEntireArray dataArray, array(seriesIndex)	're-sort by series
	end if
end function

function plotXYLineSeries(byval xIndex, byval yIndex _
	, byref dataArray, byval colorExpr, byval thickness _
	, byval positioning, byval layerExpr)
  '
  'Description:	Plots a series in an X,Y line graph
  'Note:		The x and y coordinates must *already* be scaled to the drawing
  '				region.
  'Parameters:	xIndex		- The index of the column containing the X values
  '				yIndex		- The index of the column containing the Y values
  '				dataArray	- The data array
  '				colorXExpr	- Expression to use to calculate the colour.
  '				positioning	- "absolute" or "relative" - how to position the graph
  '
  Dim rowIndex	'index into the data array
  Dim x1, y1	'coordinates for the start of the next line segment
  Dim x2, y2	'coordinates for the finish of the next line segment
  Dim thisRow	'the current data row
  dim lastRow	'the previous data row
  dim layerAttr	'the evaluation of layerExpr for the current data row
   
  if colorExpr="" then colorExpr = chr(34) & "red" & chr(34)
  if positioning="" then positioning = "absolute"
    
  If not isempty(dataArray) Then
    for rowIndex = lbound(dataArray) to ubound(dataArray)
      x2 = dataArray(rowIndex)(xIndex) 
      y2 = dataArray(rowIndex)(yIndex) 
      thisrow = dataArray(rowIndex)
      if lbound(dataArray)<rowIndex Then      
        if (not isnull(x2)) and (not isnull(y2)) Then
          if ""<layerExpr then layerAttr=eval(layerExpr)
          plotLine Array(x1,y1), array(x2,y2), positioning, Eval(colorExpr) _
			,thickness, layerAttr
        end If
      end if
      lastRow = thisrow
      x1 = x2
      y1 = y2
    next 
  End If
end function

function plotPositionStart(byval x, byval y, byval positioning, byval layerAttr)    
  '
  'Description:	Set the current rendering coordinates for the browser.
  'Notes:		This is the lowest level plotting routine.  All the others
  '				are layered on top of it.  plotBlock, for example, calls
  '				this to set the (top,left) coordinates for the block it
  '				is about to plot. plotLine, in turn, uses plotBlock to
  '				plot straight line segments.
  '
  x=int(x+.5): y=int(y+.5)
  if isNetscapeLayerBrowser() then
    Response.Write "<LAYER position=" & positioning & " top=" + cstr(int(y+.5)) + " left=" + cstr(int(x+.5)) 
  else
    if lcase(positioning) = "relative" Then
      Response.Write "<DIV style=""position:" & positioning & "; Top:" + cstr(int(y+.5)) _
			+ "; Left: " + cstr(int(x+.5)) + """" 
    else
      Response.Write "<DIV style=""position:" & positioning & "; top:" + cstr(int(y+.5)) _
			+ "; left: " + cstr(int(x+.5)) + """"
    end if
  end if
  if ""<layerAttr Then Response.Write " " & layerAttr
  Response.Write ">" & vbCrlf
end function

function plotPositionEnd(positioning)
  if isNetscapeLayerBrowser() Then
    Response.Write "</LAYER>"
  else
    Response.Write "</DIV>"
  end if
  Response.Write vbCrlf
end function

function plotVector(byval pointArray, byval positioning, byval color, byval thickness _
	, byval layerAttr)
  if positioning="" then positioning = "absolute"
  dim i
  dim j
  for i = lbound(pointArray) to ubound(pointArray) - 1
    j = i + 1
    plotLine pointArray(i), pointArray(j), positioning, color, thickness, layerAttr
  next
end function

function offsetPictureAttr(byval x,byval y,byval pic)
  '
  'Description:	Calculate the attributes to add to a <TABLE> tag
  '				(IE) or to a <LAYER> or <DIV> tag (NS4.7 and NS6)
  '				to display an offset picture slice.
  'Parameters:	x   =   current X coordinate
  '				y   =   current Y coordinate
  '				pic =   URL of image to display (should not contain
  '						spaces)
  'Explanation:	To display a picture in an area built by rendering
  '				lots of narrow vertical tables (e.g. stacked area)
  '				or lots of narrow horizontal tables (e.g. pie),
  '				you need to separately offset the background picture
  '				in each of the tables.  
  '
  x= int(x+.5): y = int(y+.5)
  if isNetscapeLayerBrowser() then
    offsetPictureAttr =  _
	 " style=" & chr(34) & "background-image: URL(" & pic & "); " _
	& " background-repeat:repeat; " & chr(34) 
	'Todo: should add something like this:
	'  & " clip=""rect(" & chr(34) & cstr(y) & " 50 50 " & cstr(x) & """)"
	' ... when I get the right for Netscape.
	'Caveat. For netscape, space characters in the pic parameter stop this from
	'working correctly.  Please use references to URLs that do not contain spaces.
  else
  offsetPictureAttr =  _
	 " style=" & chr(34) & "background-image: URL(" & pic & "); " _
	& " background-repeat:repeat; background-position:" & cstr(-x) & "px " _
	& cstr(-y) & "px;" & chr(34)
  end if
end function

function pictureAttr(byval pic)
  pictureAttr = "BACKGROUND=" & chr(34) & pic & chr(34)
end function

function plotBlock(byval leftTop, byval RightBottom, byval positioning, byval color _
	, byval attr, byval content, byval layerAttr)
  '
  'Description:	Plots a rectangular block using <TABLE>, <TR> and <TD>.
  '				Also uses <LAYER> for NS4.7 and earlier, and <DIV> for NS6.
  'Parameters:	leftTop     - Array(x1,y1) - the left and top coordinates
  '				rightBottom - Array(x2,y2) - the right and bottom coordinates
  '				positioning - either "absolute" or "relative"
  '				color		- the background color to be used for the <TD>.
  '							  may be "".
  '				attr		- Attributes for the <TABLE> tag
  '				content		- HTML content to display *inside* the <TD>
  '				layerAttr	- layer attribute to pass to Netscape 4 (or 6!)
  'Notes:		This routine is used for plotting axes, bars, horizontal
  '				slices of pies, and vertical slices of stacked area charts
  '				You don't need to pass leftTop and rightBottom in the right
  '				order.  
  '
  Dim x			'actual left coordinate (usually leftTop(0)).
  Dim y			'actual top coordinate  (usually leftTop(1)).
  Dim width		'actual width of the table cell
  Dim height	'actual height of the table cell
  
  width = abs(RightBottom(0) - leftTop(0)) + 1
  height = abs(Rightbottom(1) - leftTop(1)) + 1
  x = leftTop(0)
  y = leftTop(1)
  if rightBottom(0)<x Then x=rightBottom(0)
  if rightBottom(1)<y Then y=rightBottom(1)  
  if width<1 then width=1
  if height<1 then height = 1
  
  plotPositionStart x, y, positioning, layerAttr
    attr = trim(attr & " width=" & cstr(int(width)) & " height=" & cstr(int(height)))
    if isNetscape6Browser Or isNetscapeLayerBrowser Then attr=attr & " border=0"
    Response.Write "  <TABLE " & attr & "><TR>"
    Response.Write "<TD"
    if ""<color Then Response.Write " bgcolor=" & color 
    'if isNetscapeBrowser() Then Response.Write " valign=bottom halign=right"
    if (content="") and (isNetscape6Browser() or isNetscapeLayerBrowser) then 
      Response.Write " valign=bottom halign=right"
      content = content & "<IMG HREF=""trans1x1.gif"" alt="""" width=1 height=1"
      if ""<color Then content = content & " bgcolor=" & color 
      content = content & ">" '& "</LAYER></ILAYER>"
      '--workaround needed for NS.  Unless there is something to show in the table
      '  cell, Netscape does not render it at all.  
      '  That's why we put in the reference to the transparent 1x1 GIF file.
    end if
    Response.Write ">" & content 
    Response.Write "</TD>"
    Response.Write "</TR></TABLE>" & vbCrlf
  plotPositionEnd positioning
end function

sub swapVariants(byref a, byref b)
  dim temp
  if isobject(a) Then set temp = a else temp = a
  if isobject(b) then set a = b else a = b
  if isobject(temp) then set b = temp else b = temp
end sub

function plotLine(byval startPoint, byval endPoint, byval positioning, byval color _
	, byval thickness, byval layerAttr)
	'
	'Description:	Plots a line between two points
	'Parameters:	startPoint(0), startPoint(1) - x and y coordinates of start
	'				endPoint(0), endPoint(1) - x and y coordinates of end
	'				positioning - whether to use "absolute" or "relative" positioning
	'				color - the color to use
	'				thickness - how thick the line is to be drawn
	'
	if isempty(thickness) then thickness = 1
	dim leftbit		
	dim rightbit
	leftbit = int(thickness/2)
	rightbit = thickness - leftbit
	if startPoint(0)=endPoint(0) or startPoint(1)=endPoint(1) then
		'Is vertical or horizontal
		startPoint(0) = startPoint(0) - leftBit
		endPoint(0) = endPoint(0) + rightBit	
	    startPoint(1) = startPoint(1) - leftBit
	    endPoint(1) = endPoint(1) + rightBit
		plotBlock startPoint, endPoint, positioning, color, "", "", layerAttr
		'DumpParameters "plotBlock", Array(startPoint, endPoint, positioning, color, "", "", layerAttr)
	else
	  dim x,y,jump,x2,y2	'While rendering
	  if abs(startPoint(0)-endPoint(0)) > abs(startPoint(1)-endPoint(1)) Then
	    'X difference is greater, so step through Y's
	    if endPoint(1)<startPoint(1) then swapVariants startPoint,endPoint
	    x = startPoint(0) 
	    jump = (endPoint(0)-startPoint(0)) / (endPoint(1)- startPoint(1))
	    for y = startPoint(1) to endPoint(1)	      
	      x2 = x+jump+rightbit*sgn(jump)
	      if sgn(x2 - endPoint(0) - rightbit*sgn(jump) ) = sgn(jump) Then
	        x2 = endPoint(0) + rightbit*sgn(jump)
	      end if	      
	      plotBlock Array(x-leftbit*sgn(jump),y-leftbit) _
			, Array(x2,y+rightbit), positioning, color, "", "", layerAttr
			'Todo: Might want to supply attributes too!
		  x = x + jump
	    next	    
	  else
	    'Y difference is greater, so step through X's
	    if endPoint(0)<startPoint(0) then swapVariants startPoint, endPoint
	    y = startPoint(1) 
	    jump = (endPoint(1)-startPoint(1)) / (endPoint(0)- startPoint(0))
	    for x = startPoint(0) to endPoint(0)
	      y2 = y+jump+rightbit*sgn(jump)
	      if sgn(y2 - endPoint(1) - rightbit*sgn(jump) ) = sgn(jump) Then
	        y2 = endPoint(1) + rightbit*sgn(jump)
	      end if	      
	      plotBlock  Array(x-leftbit,y-leftbit*sgn(jump)) _
			, Array(x+leftbit,y2), positioning,  color, "", "", layerAttr
		  y=y+jump
	    next
	  End If		
	end if
end function

function cstrn(number,digits)
  dim result
  result = cstr(number)
  if len(result) < digits then
    result = string(digits-len(result), "0") & result
  end if
  cstrn = result
end function

function secondfraction(byval datetime,byval denominator)
  datetime = datetime * 60 * 60 * 24	'convert to seconds
  datetime = datetime - int(datetime)	'strip off whole number
  numerator = int(datetime * denominator)
  secondfraction = cstrn(numerator, len(denominator)-1)
end function

function selectdateUnit(byval range, byval pixelsize, byref dateFormula)
  Dim unitArray  
  Dim realrange
  Const second= #0:0:1#
  realrange = abs(range(1) - range(0))	'get range in days
  unitArray = Array(365,"yyyy",28,"dd/mm/yyyy",14,"dd/mm/yyyy" _
	,7,"dd/mm",2,"dd/mm",1,"dd/mm",#6:0#,"hh:nn dd/mm" _
	,#3:0#, "hh:nn dd/mm", #1:0#, "hh:nn", #0:30#, "hh:nn" _
	,#0:15#, "hh:nn", #0:5#, "hh:nn", #0:1#, "hh:nn" _
	,#0:0:30#, "hh:nn:ss", #0:0:15#, "hh:nn:ss", #0:0:10#, "nn:ss" _
	,#0:0:05#, "nn:ss", #0:0:1#, "nn:ss", second/10, "nn:ss.xx" _
	,second/100, "ss.xx", second/1000, "ss.uu" )
  dim TryUnit
  for tryUnit = lbound(unitArray)+2 to ubound(unitArray)-3 step 2
    if realrange / unitArray(tryUnit) > pixelsize/8/len(unitARray(tryUnit+1))  then
      tryUnit = tryUnit - 2
      exit for
    end if
  next    
  dateFormula = chr(34) & unitArray(tryUnit+1) & chr(34)
  if int(range(0))=0 and int(range(1))=0 Then
    'Time only, no date component
    dateFormula = replace(dateFormula, "/", "")
    dateFormula = replace(dateFormula, "yyyy", "")
    dateFormula = replace(dateFormula, "mm", "")
    dateFormula = replace(dateFormula, "mmm", "")
    dateFormula = replace(dateFormula, "dd", "")
  end if
  dateFormula = replace(dateFormula, "yyyy", chr(34) & " & cstr(year(value))& " & chr(34))
  dateFormula = replace(dateFormula, "mm", chr(34) & " & cstrn(month(value),2) & " & chr(34))
  dateFormula = replace(dateFormula, "mmm", chr(34) & "& monthname(month(value)) & " & chr(34))
  dateFormula = replace(dateFormula, "dd", chr(34) & " & cstrn(day(value),2)& " & chr(34))
  dateFormula = replace(dateFormula, "hh", chr(34) & " & cstrn(hour(value),2)& " & chr(34))
  dateFormula = replace(dateFormula, "nn", chr(34) & " & cstrn(minute(value),2)& " & chr(34))
  dateFormula = replace(dateFormula, "ss", chr(34) & " & cstrn(second(value),2)& " & chr(34))
  dateFormula = replace(dateFormula, "xx", chr(34) & " & cstr(secondfraction(value,100))& " & chr(34))
  dateFormula = replace(dateFormula, "uu", chr(34) & " & cstr(secondfraction(value,1000000))& " & chr(34))      
  selectDateUnit = unitArray(tryUnit)
end function

function selectunit(byval range, byval pixelsize, byref displayFormula)
  '
  'Description:	Given a range, and a width in pixels, decide how many
  '				values to plot (on an X or Y axis), and what "step"
  '				to use between values.
  'Notes:		The units selected are *not* appropriate for timestamp
  '				values.  It'd be a good idea to build a version of this
  '				routine for calculating *timestamp* units.
  'See Also:	The axis plotting routines, which have *real* problems
  '				plotting date or timestamp information.
  '
  dim powerOfTen	'
  Dim fractional	'
  Dim unit			'Fundamental unit to display along axis

  if typename(range(0)) = "Date" Then
    selectUnit = selectdateUnit(range, pixelsize, displayFormula)
    exit Function
  End If
  
  if range(1)=range(0) then
    selectUnit = 1
    exit function
  end if
  powerofTen = log(cdbl(abs(range(1) - range(0)))) / log(10) - _
	log(pixelSize/40) / log(10)
  
	
  fractional = powerOfTen - int(powerOfTen)
  powerOfTen = int(powerOfTen)
  
	if fractional< log(2)/log(10) Then
	  unit = exp(poweroften*log(10))
	elseif fractional<  log(5)/log(10) then
	  unit = 2 * exp(poweroften*log(10))
	else
	  unit = 5 * exp(poweroften*log(10))
    end if	  

  selectunit = unit 
end function  

function plotXAxis(byval range, byval rect, byval color, byval axisName _
	, byval minStep, byval stringValueArray)
  'Description: plots an X axis for a graph
  'Parameters:	range(0) - lower value bound
  '				range(1) - upper value bound
  '				rect(0)	 - minimum X plotting coordinate
  '				rect(1)  - minimum Y plotting coordinate
  '				rect(2)  - maximum X plotting coordinate
  '				rect(3)  - maximum Y plotting coordinate
  '				rect(4)  - absolute/relative position
  'Notes:		Plotting of date/time information sucks.  Sorry about that.
  '				It'd better be multiple days to be plotted, because all
  '				date/time values are formatted as "dd/mm".  It's bad, I know.
  '														-JB
  '				
  if color="" then color=chr(34) & "black" & chr(34)
  if ubound(rect)=3 then AddelementToArray "absolute", rect
  if rect(4) = "" then rect(4) = "absolute"
  plotLine   Array(rect(0),(rect(1)+rect(3))/2), Array(rect(2),(rect(1)+rect(3))/2) _
	, rect(4), color, 1 , ""
  Dim unit
  dim value
  dim x
  Dim ybarlow
  dim ybarhigh
  dim displayFormula
  dim axis
  axis = "X"
  unit = selectUnit(range, int(abs(rect(2) - rect(0))), displayFormula)
  plotline Array(rect(0), rect(1)), Array(rect(0), rect(3)), rect(4), color, 1, "" 'Min
  'DumpParameters "plotLine", Array(Array(rect(0), rect(1)), Array(rect(0), rect(3)), rect(4), color, 1, "")
  plotline Array(rect(2), rect(1)), Array(rect(2), rect(3)), rect(4), color, 1, "" 'Max
  ybarlow = rect(1) * 0.75 + rect(3) * 0.25
  ybarhigh = rect(1) * 0.25 + rect(3) * 0.75  
  if minStep=1 then if unit < minStep then unit = minStep
  for value = int(range(0) / unit) * unit to range(1) step unit
    dim formattedValue
    if range(0)<value then
      if displayFormula="" then
        if not isempty(stringValueArray) Then
          'Response.Write "XZ: " & value & " in " & Join(stringValueArray,",") & "<BR>" & vbCrlf
          formattedValue = cstr(stringValueArray(value))
        else
          formattedValue = cstr(value)
        end if
      else 
        formattedValue = eval(displayFormula)      
	  end if
      x = (value - range(0)) / (range(1) - range(0)) * (rect(2) - rect(0)) + rect(0)
	  if graphImpliedGridY Then
	    plotLine Array(x,ybarhigh), Array(x,graphTop), rect(4), eval(graphGridColorExpr),1, ""
	  end if	        
      plotLine Array(x,ybarlow), Array(x,ybarhigh), rect(4), color, 1, ""
      plotPositionStart x - len(formattedValue)*4, max(ybarlow,ybarhigh), rect(4), ""
        Response.Write Server.HTMLEncode(formattedValue)
      plotPositionEnd rect(4)
    end if
  next 
  if ""<AxisName Then
    plotPositionStart rect(0)*.5 + rect(2)*.5 - len(AxisName)*10 _
	  , max(rect(3), rect(1))+8, rect(4), ""
      Response.Write "<H2>" & server.HTMLEncode(AxisName) & "</H2>"
    plotPositionEnd rect(4)
  end if
end function

function plotYAxis(byval range, byval rect, byval color, byval axisName, byval minStep _
	, stringValueArray)
  '
  'As per plotXAxis.  Captions are rendered to the *left* of the axis
  '
  if ubound(rect)=3 then AddelementToArray "absolute", rect
  if rect(4) = "" then rect(4) = "absolute"
  plotLine  Array((rect(0)+rect(2))/2,rect(1)), Array((rect(0)+rect(2))/2, rect(3))  _
	, rect(4), color, 1    , ""
  Dim unit
  dim value
  dim y
  Dim xbarlow
  dim xbarhigh
  Dim displayFormula
  dim axis
  axis = "Y"
  unit = selectUnit(range, int(abs(rect(3) - rect(1))), displayFormula)
  if minStep=1 then if unit < minStep then unit = minStep
  plotline Array(rect(0), rect(1)), Array(rect(2), rect(1)), rect(4), color, 1, "" 'Min
  plotline Array(rect(0), rect(3)), Array(rect(2), rect(3)), rect(4), color, 1, "" 'Max
  xbarlow = rect(0) * 0.75 + rect(2) * 0.25
  xbarhigh = rect(0) * 0.25 + rect(2) * 0.75    
  
  for value = int(range(0) / unit) * unit to range(1) step unit
    dim formattedValue
    if range(0)<value then
      if ""=displayFormula Then
        if not isempty(stringValueArray) Then
          'Response.Write "XZ: " & value & " in " & Join(stringValueArray,",") & "<BR>" & vbCrlf
          formattedValue = cstr(stringValueArray(value))
		else
		  formattedValue = cstr(value)
		end if
	  else
	    formattedValue = eval(displayFormula)
	  end if
      y = (value - range(0)) / (range(1) - range(0)) * (rect(3) - rect(1)) + rect(1)
	  if graphImpliedGridX Then
	    plotLine Array(xbarlow,y), Array(graphWidth+graphLeft,y), rect(4), eval(graphGridColorExpr),1, ""
	  end if	        
      plotLine Array(xbarlow,y), Array(xbarhigh,y), rect(4), color, 1, ""
      plotPositionStart xbarlow-len(cstr(formattedValue))*8, y-5, rect(4), ""
        Response.Write Server.HTMLEncode(formattedValue)
      plotPositionEnd rect(4)
    end if
  next 
  if ""<AxisName Then
    plotPositionStart rect(0)*.5 + rect(2)*.5 - len(AxisName) * 4 _
		, min(rect(1),rect(3))-18, rect(4), ""
      Response.Write "<H2>" & server.HTMLEncode(AxisName) & "</H2>"
    plotPositionEnd rect(4)
  end if
end function

function differentValuesInColumn(byval thisArray, byval thisIndex)
  '
  'Description:	Returns an array containing the distinct values found
  '				for the specified column of an array of arrays.
  'Notes:		As a side-effect, trashes the order of the array
  '				of arrays.
  'Parameters:	thisArray - array of arrays
  '				thisIndex - index to sort on
  '
  dim result
  dim rowIndex
  if not isempty(thisArray) Then
    mergeSortEntireArray  thisArray, array(thisIndex)
    AddElementToArray thisArray(lbound(ThisArray))(thisIndex), result
    for rowIndex = lbound(thisArray)+1 to ubound(thisArray)      
      if CompareVariants(thisArray(rowIndex)(thisIndex) _
		, thisARray(rowIndex-1)(thisIndex))<>0 Then
		AddElementToArray thisArray(rowIndex)(thisIndex), result
	  End If
    next
  end if
  differentValuesInColumn = Result
end function

function plotPieSlice(byval cx, byval cy, byval w, byval h _
	, byval radianStart, byval radianEnd, byval thisRow, byval attrexpr _
	, byval colorExpr , byval positioning, byval layerExpr)
	dim tryY
	dim p		'Number of points around the circumference
	dim edgeX	'Current point on the edge of the circle
	dim edgeY	'Current point on the edge of the circle
	dim j
	dim lastedgeY
	dim pixelArray
	dim angle
	dim atLeft
	dim drawLeft
	dim i
    dim nextedgeY
    dim thisEdgeY
	
	'Response.Write "XZ: Pie slice " & radianStart & " to " & radianEnd & "<BR>" & vbCrlf
	lastEdgeY = -999
	if radianStart<radianEnd Then
	
	  '
	  'find circle edge points actually used
	  '
	  p = (w * w + h * h) ^ 0.5
	  for j = radianStart to radianEnd step 3.1415926 / p / 2
	    edgeX = cx + sin(j) * w
	    edgeY = cy + cos(j) * h
	    if lastedgeY <> int(edgeY+.5)then
	      nextEdgeY  = int(edgeY + .5)
	      if lastEdgeY<>-999 then
	      for thisEdgeY = lastEdgeY + sgn(nextEdgeY - lastEdgeY) to nextEdgeY step sgn(nextEdgeY - lastEdgeY)
	        addElementToArray Array(int(edgeX+.5),thisEdgeY,iif(int(edgeX+.5)<cx,0,7)), pixelArray
	        'column 2 is 0 if point is left of centre of circle, 7 if right or centred
	      next 
	      else
	        addElementToArray Array(int(edgeX+.5),nextEdgeY,iif(int(edgeX+.5)<cx,0,7)), pixelArray
	      end if
	      lastEdgeY = nextEdgeY
	    end if
	  next
	  
	  '
	  'find line points actually used
	  '
	  'Response.write "KKK: " & radianEnd - radianStart & ", " & (3.1415926 * 2) & "<BR>" & vbCrlf
	  if abs(radianEnd - radianStart - 3.1415926 * 2)>1E-7 Then
	  lastEdgeY = -999
	  dim maxsin
	  dim thisSin, thisCos
	  dim sameCosSign
	  maxsin = max(sin(radianStart), sin(radianEnd))
	  sameCosSign = abs(sgn(cos(radianStart))+sgn(cos(radianEnd))) = 2
	  for each angle in Array(radianStart, radianEnd)
	    thisSin = sin(angle)
	    thisCos = cos(angle)
		if sameCosSign then
		  atLeft= iif(thisSin<maxsin,0,4)
		else
		  atLeft= iif(radianStart<radianEnd Xor thisCos<0,4,0)		  
		end if
	    drawLeft = iif((Not thisSin<maxSin),1,2)
	      'wrong. could be at left with other coordinate at left too. if signs differ
	    if drawleft=1 and not(sameCosSign) and 0<thisCos and 0<thisSin then drawLeft = 2
	    if drawleft=1 and not(sameCosSign) and thisCos<0 and 0<thisSin then drawLeft = 2
	    if drawleft=2 and not(sameCosSign) and  thisSin<0 then drawLeft =1 '0<thisCos and
	    
		'Response.Write "QQQ: X=" & thisSIn & ", Y=" & thisCos & "<BR>" & vbCrlf
		'Response.Write "QQQ: atLeft = " & atLeft & ", drawLeft = " & drawLeft & "<BR>" & vbCrlf

	    for j = 0 to w 'assumes h<w which is dicy
	      edgeX = cx + thisSin * j
	      edgeY = cy + thisCos * j * (h/w)	'assumes h<w which is dicy
	      if lastedgeY <> int(edgeY+.5) then
	        lastedgeY  = int(edgeY + .5)
	        addElementToArray Array(int(edgeX+.5),lastEdgeY,atLeft+drawLeft), pixelArray
	          'column 2 is:
	          ' 1 if at left and we are to draw to the left
	          ' 2 if at left and we are to draw to the right
	          ' 5 if at right and we are to draw to the left
	          ' 6 if at right and we are to draw to the right
	      end if	    
	    next
	  next
	  end if
	  
	  mergeSortEntireArray pixelArray, array(1,2,0)	'sort by Y
	  
	  '
	  'we now have all the dots along the edges of the shape
	  'we draw when we have adjacent rows in the array with
	  'matching column 1 (Y) and column 2 value pairs of:
	  '(0,7), (0,1), (0,5), (2,7), (6,7), (2,5)
	  'We do NOT draw when the column 2 value pairs are:
	  '(0,2), (0,6), (1,5), (1,6), (1,7), (2,6), (5,6), (5,7)
	  'Okay, I grant you, this is weird, but bear with us...
	  '
	  
	  '
	  'Todo: special case: may have lots of 77 and 00 for horizontal
	  'lines drawn out from the centre!
	  '
	  
	  for i = 1 to ubound(pixelArray)
	    if pixelArray(i-1)(1) = pixelArray(i)(1) then
	      if 0 < instr(1, "07-01-05-27-67-25-", pixelArray(i-1)(2) & pixelArray(i)(2) & "-") then
	        dim x,y
	        dim attrValue
	        dim layerAttr
	        x= pixelArray(i-1)(0)
	        y= pixelArray(i-1)(1)
	        if ""<attrExpr then attrValue = eval(attrExpr)
	        if ""<layerExpr then layerAttr = eval(layerExpr)
	        plotBlock   array(pixelArray(i-1)(0), pixelArray(i-1)(1)) _
				, array(pixelArray(i)(0), pixelArray(i)(1)), positioning, colorExpr, attrValue, "", layerAttr
	      end if
	    end if
	  next
	  
	  
	end if
end function

function quickSeriesPlot(byval xIndex, byval yIndex, byval expr, byval dataArray _
	, Byval XAxisTitle, byval YAxisTitle, byval offsetXexpr, byval offsetYexpr _
	, byval positioning, byval graphType, byval seriesIndex , byval zAxisTitle _
	, byval seriesTitleExpr, byval seriesColorExpr, byval layerExpr)
  '
  'Description:	multiple-series plotting algorithm.
  'Parameters:	Update this list. Some are now missing, since I killed off quickPlot().				
  '		seriesIndex		- the index of the column in the input array that
  '						  contains the field used to differentiate one series
  '						  from another
  '		zAxisTitle		- not used at present.
  '						  Should be caption for the list of series.
  '		seriesTitleExpr	- expression to evaluate to derive each series title
  '						  (the "value" variable will have the value form the
  '						  seriesIndex column.  thisRow will *not* be defined)
  '		seriesColorExpr	- expression to evaluate to derive each series colour.
  '						  if "" is supplied, see defaultColorArray below
  '						  for the default range of colours.
  '		layerExpr		- expression to pass when plotting any layers (for NS
  '						  which only does background on LAYER tags).
  'Notes:	The list of series names and colours is shown at the bottom of the
  '			graph.  It *could* be shown at the right, with some changes.
  '
  dim seriesValue		'Value in series column
  dim value				'Ditto
  dim color				'Color to use for this series (constant, not expression)
  dim title				'Title to use for this series 
  Dim seriesNumber		'Series number, counting 1 and up
  Dim filteredData		'Rows for this series
  Dim tIndex			'Top index (for stacked bar and area graphs)
  Dim bIndex			'Bottom index (for stacked bar and area graphs)
  Dim x2Index			'end-time index (for gannt charts)
  Dim minMax			'Minima and maxima used for scaling graph
  dim seriesValueArray  'Array of values of the series
  dim xIndexArray		'Columns to be scaled for X axis
  dim yIndexArray		'Columns to be scaled for Y axis
  dim isBarGraph		'True if bar graph logic needs to be applied in
						'prepareToGraph().  This is NOT necessary for all
						'bar graph types
  dim thisRow					
  
  if positioning="" then positioning = "absolute"
  if seriesTitleExpr = "" then seriesTitleExpr = """Series "" & cstr(seriesNumber)"
  seriesValueArray = differentValuesInColumn(dataArray, seriesIndex)
  if not isArray(xIndex) then xIndexArray = Array(xIndex) else xIndexArray=xIndex
  if not isArray(yIndex) then yIndexArray = Array(yIndex) else yIndexArray=yIndex
  
  isBarGraph = 0<instr(graphType, "bar")
  
  Select case lcase(graphType)
	case "area"
	  stackDataArray xIndex, yIndex, dataArray, Null, tIndex, bIndex
	  yIndexArray = Array(tIndex, bIndex)
    case "stacked area", "stacked bar"
	  stackDataArray xIndex, yIndex, dataArray, seriesIndex, tIndex, bIndex	  
	  yIndexArray = Array(tIndex, bIndex)
	case "bar"
	  'default is to do bar graphs with side-by-side bars (if more than 1 series)
	  'to explicitly overlay series, use "overlay bar".
	  if 0 < ubound(seriesvalueArray) Then
	    '1. calculate nominal bar width if there were only 1 series = fatbar
	    '2. divide that by the number of series to get              = thinbar
	    '3. for each row, offset thisRow(x) by the index of the series value, i
	    '     thus: x = x + (i - (seriesCount/2)) * thinbar
	    'Todo: make this another function
	    dim nominalBarWidth, thinBar, rowIndex, i
	    nominalBarWidth = getMinimumDifferenceForColumn(dataArray, xIndex)
	    if nominalBarWidth = 0 then nominalBarWidth = 1		
	      'doesn't matter what this # is, so long as it is not zero
	    thinBar = nominalBarWidth / (ubound(seriesvalueArray)+1) * .8
	    for rowIndex = lbound(dataArray) to ubound(dataArray)
	      for i = lbound(seriesValueArray) to ubound(seriesValueArray)
	        if dataArray(rowIndex)(seriesIndex) = seriesValueArray(i) Then
	          exit for
	        end if
	      next
	      dataArray(rowIndex)(xIndex) = dataArray(rowIndex)(xIndex) _
	        + (.5 + i - (ubound(seriesvalueArray)+1)/2) * thinBar
	    next	    
	  end If
	case "gannt"
	  x1Index = xIndex(0)
	  x2Index = xIndex(1)
	  
	  if 0 < ubound(yIndex) then hIndex = yIndex(1)	'height for individual bars supplied too
	    'Note that this isn't supported yet.
	case "pie"	  
	  if  isnull(xIndexArray(0)) then
	    'Response.Write "XZ: pie processing: dummy X column<BR>" & vbCrlf
	    AddEmptyColumnsToArray 1, ubound(dataArray(0))+1, dataArray
	    xIndexArray(0) = ubound(dataArray(0))
	    xIndex = xIndexArray(0)  
	    'Response.Write "XZ: pie processing: dummy X column is " & xIndex & "<BR>" & vbCrlf
	    'DumpArrayOfArraysAsTable dataArray,2,false 'XZ
	  end if
	  'Response.Write "XZ: pie processing: stacking by X<BR>" & vbCrlf
	  stackDataArray xIndex, yIndex, dataArray, seriesIndex, tIndex, bIndex	  
	  'Response.Write "XZ: pie processing<BR>: rescaling by X" & vbCrlf
	  rescaleColumnsOfArray Array(tIndex), Array(0), Array(3.1415926*2), (dataArray), minMax
	  if 0<minMax(0)(0) then minMax(0)(0)=0 'wrong
	  AdjustMinMax bIndex, dataArray, minMax(0) 'wrong
	  rescaleColumnsOfArray Array(tIndex), Array(0), Array(3.1415926*2), dataArray, minMax
	  rescaleColumnsOfArray Array(bIndex), Array(0), Array(3.1415926*2), dataArray, minMax
	  yIndexArray = Array(bIndex, tIndex)
	  'Response.Write "XZ: pie scaled<BR>" & vbCrlf
  End Select	  

  if lcase(graphType)<>"pie" then
    prepareToGraph xIndexArray, yIndexArray, dataArray, XAxisTitle, YAxisTitle, positioning _
      , false, false, isBarGraph  , lcase(graphType)="gantt", 0.5, minMax      
  end if
  
  if graphType="bar" then
    thinBar = thinBar / (minmax(0)(1) - minmax(0)(0)) * (graphWidth)	'Todo: drop hardcoding here
  end if
   
  Dim defaultColorArray
  defaultColorArray = graphDefaultColorArray 
  if seriesColorExpr = "" Then
    'If no colour rule supplied, choose based on series
    seriesColorExpr = "defaultColorArray(SeriesNumber mod (ubound(defaultColorArray)+1))"  
  end If  

  if lcase(graphType)="pie" then
    plotPieCharts xIndexArray, yIndexArray, expr, dataArray, positioning, seriesIndex _
		, seriesTitleExpr, seriesColorExpr, layerExpr
    exit function
  end if    
    
  for each seriesValue in seriesValueArray
    value = seriesValue
    seriesNumber = seriesNumber + 1
    color = eval(seriesColorExpr)
    title = eval(seriesTitleExpr)
    filteredData = filteredArray((dataArray), Array(seriesIndex), Array(seriesValue))
    Select case lcase(graphType)
      case "","scatter" 
        plotXYScatterSeries xIndex, yIndex, filteredData, expr, offsetXexpr, offsetYexpr _
  	      , positioning, layerExpr
  	  case "bar overlay", "bar"
  	    plotBarseries Array(xIndex), Array(yIndex), filteredData, expr, chr(34) & color & chr(34), graphHeight+graphTop, positioning _
  			, thinBar, layerExpr, dataArray
  	  case "line"
  	    plotXYLineSeries xIndex, yIndex, filteredData, chr(34) & color & chr(34), 2, positioning, layerExpr
  	  case "line+point"
  	    plotXYLineSeries xIndex, yIndex, filteredData, chr(34) & color & chr(34), 2, positioning, layerExpr
        plotXYScatterSeries xIndex, yIndex, dataArray, expr, offsetXexpr, offsetYexpr _
  	      , positioning, layerExpr
  	  case "stacked area", "area"
  	    plotXTBAreaSeries xIndex, tIndex, bIndex, filteredData, chr(34) & color & chr(34) _  			
  			, positioning, expr, layerExpr
  	  case "stacked bar"
  	    plotBarSeries xIndexArray, Array(tIndex,bIndex), filteredData _
  			, expr, chr(34) & color & chr(34), graphHeight+graphTop, positioning, empty, layerExpr, dataArray
  	  case "gantt"
  	    plotBarSeries xIndexArray, yIndexArray, filteredData _
  			, expr, chr(34) & color & chr(34), graphHeight+graphTop, positioning, empty, layerExpr, dataArray
  	  case "pie"
    end select
    thisRow = filteredData(0)
    dim isPointGraph
    isPointgraph = instr(1,lcase(graphType),"point")
    writeSeriesLabel seriesNumber-1, color, title, positioning, graphLeft, graphHeight + graphTop + 30 _
		, iif(isPointGraph,"",expr) , layerExpr, thisRow
  next
end function

function plotPieCharts(byval xIndexArray, byval yIndexArray, byval Attrexpr _
	, byref dataArray, byval positioning, byval seriesIndex _
	, byval seriesTitleExpr, byval seriesColorExpr, byval layerExpr)
  
  dim xValueArray
  dim x 
  dim thisRow
  dim cx, cy, w, h
  dim pieCount
  dim piesAcross, pieX	'pies to draw in each row across the graph
  dim piesDown, pieY	'pies to
  dim xSubset			'subset of data array with matching X value
  dim seriesValueArray	'array of series found for current X value
  dim seriesValue		'next
  dim xvSubset			'subset of data array with matching X AND series values
  dim seriesNumber		'

  'Response.Write "XZ: in plotPieCharts<BR>" & vbCrlf
  'Response.Write "XZ: seriesColorExpr is " & seriesColorExpr & "<BR>" & vbCrlf
  if isNull(xIndex) then
    xValueArray=Array("")
  else  
    'Response.Write "XZ: getting values for col " & xIndex & "<BR>" & vbCrlf
    xValueArray = differentValuesInColumn(dataArray, xIndex)
  end if
  pieCount = ubound(xValueArray) + 1	'Number of pies
  piesDown = int(sqr(pieCount)*graphHeight/graphWidth+.5)
  if piesDown = 0 then piesDown = 1
  if pieCount < piesDown then piesDown = pieCount
  piesAcross = int((pieCount+piesDown-1)/piesDown)
  w = int(graphWidth/2/piesAcross) * .9
  h = int(graphHeight/2/piesDown) * .9
  if h<w then w=h else h=w 'Todo: what about aspect ratios here though?!
  Dim defaultColorArray
  defaultColorArray = graphDefaultColorArray 
  
  for each x in xValueArray 
	cx = int(graphLeft + graphWidth / piesAcross * (pieX+.5)): 
  	cy = int(graphTop + graphHeight / piesDown * (pieY+.5)): 
	if isNull(xIndex) then 
	  xSubset = dataArray
	else
	  xSubset = filteredArray((dataArray), Array(xIndex), array(x))
	end if
	
	'Rescale series values for this value of X so they add to 2*PI
	dim minMax
	minMax = empty
	AdjustMinMax yIndexArray(0), xSubset, minmax
	AdjustMinMax yIndexArray(1), xSubset, minmax
	RescaleColumnsOfArray yIndexArray,Array(0,0),Array(3.1415926*2,3.1415926*2) _
		, xSubset, Array(minMax,minMax)
	
	seriesValueArray = differentValuesInColumn(xSubset, seriesIndex)
	SeriesNumber = 0
    for each seriesValue in seriesValueArray          
  	  xvsubset = filteredArray((xSubset), Array(seriesIndex), Array(seriesValue))
  	  if not isempty(xvsubset) then
  	    thisRow = xvsubset(0)
  	    'Response.Write "XZ: SeriescolorExpr = " & SeriescolorExpr & "<BR>" & vbCrlf
  	    plotPieSlice  cx,cy,w,h,thisRow(yIndexArray(0)), thisRow(yIndexArray(1)) _
  			, thisRow, Attrexpr, chr(34) & eval(SeriescolorExpr) & chr(34), positioning, layerExpr
  		if ""<seriesTitleExpr Then
  		  dim angle
  		  angle = (thisRow(yIndexArray(0)) + thisRow(yIndexArray(1)))/2
  		  select case(graphPieLabel)
  		    case "inside"
  		      plotPositionStart cx+sin(angle)*w*.5 - 100, cy+cos(angle)*h*.5-6, positioning, ""  		        		      
  		      Response.write "<TABLE><TR><TD WIDTH=200 ALIGN=CENTER>"
  		    case "outside"
  		      plotPositionStart cx+sin(angle)*w - iif(sin(angle)<0,210,0) _
  				, cy+cos(angle)*w+.5 - iif(cos(angle)<0,12,0), positioning, ""
  		      Response.Write "<TABLE><TR><TD WIDTH=200 ALIGN=" & iif(sin(angle)>0,"LEFT","RIGHT") & ">"
  		  end select
  		  Response.Write eval(seriesTitleExpr)
  		  Response.Write "</TD></TR></TABLE>" & vbCrlf
  		  plotPositionEnd positioning
  		end if
  	   end if
  	   seriesNumber = seriesNumber + 1
  	   'Problem: what I have here is WRONG.
  	   ' Series number should actually be the index into
  	   ' differentValuesInColumn(***dataArray***,seriesIndex),
  	   ' where the current value is found.
  	 next
  	 
  	 plotpositionStart cx-h, cy+w, positioning, ""
  	   Response.Write "<TABLE width=" & cstr(h*2) & "><TR><TD width=" & cstr(h*2) & " HALIGN=CENTER>" & vbCrlf
  	   Response.Write "<CENTER>"
  	   Response.Write Server.HTMLEncode(x) & vbCrlf
  	   Response.Write "</CENTER></TD></TR></TABLE>" & vbCrlf
  	 plotPositionEnd positioning
  	 
  	 
  	 pieX = pieX + 1
  	 if pieX = piesAcross then pieX=0: pieY = pieY + 1
  next
end function

function prepareToGraph(byval xIndexArray, byval yIndexArray, byref dataArray _
	, Byval XAxisTitle, byval YAxisTitle, byval positioning _
	, byval ZeroXOrigin, byval ZeroYOrigin, byval isXBar, byval isYBar , byval barOffset _
	, byref minMax)
  '
  'Description:	Rescales an input array to fit a standard graphing region,
  '				and draws X and Y axes for it.
  '
  dim barX
  dim barY
  dim xIndex
  dim yIndex
  
  xIndex = xIndexArray(0)
  yIndex = yIndexArray(0)
  barX = 0
  barY = 0
  if positioning="" then positioning = "absolute"

  rescaleColumnsOfArray Array(xIndex,yIndex), Array(graphLeft,graphHeight+graphTop), Array(graphWidth+graphLeft,graphTop), (dataArray) _
	, minMax 'we pass data array by value to find the minima and maxima for the values in
			 'each index	
			 
  if 0 < ubound(xIndexArray) Then
    for each xIndex in xIndexArray: AdjustMinMax xIndex, dataArray, minMax(0): next
  end if
  xIndex = xIndexArray(0)

  if 0 < ubound(yIndexArray) Then
    for each yIndex in yIndexArray: AdjustMinMax yIndex, dataArray, minMax(1): next
  end if
  yIndex = yIndexArray(0)
		 
  if isXBar then 
    barX = getMinimumDifferenceForColumn ( dataArray, xIndex)
    minMax(0)(0) = minMax(0)(0) - (1-barOffset) * barX
    minMax(0)(1) = minMax(0)(1) + barOffset * barX
  end if
  
  if isYBar then
    barY = getMinimumDifferenceForColumn (dataArray, yIndex)
    minMax(1)(0) = minMax(1)(0) - (1-barOffset) * barY
    minMax(1)(1) = minMax(1)(1) + barOffset * barY
  end if
  
  if (zeroXOrigin or graphXOrigin) And 0 < minMax(0)(0) then minMax(0)(0) = 0	'todo: what if all are -ve ?
  if (zeroYOrigin or graphYOrigin) And 0 < minMax(1)(0) then minMax(1)(0) = 0	'todo: what if all are -ve ?


  dim stringValueArray
  if not isnull(XAxisTitle) Then
	stringvalueArray = Empty
    if Typename(dataArray(0)(xIndex))="String" Then stringValueArray = DifferentValuesInColumn(dataArray,xIndex)
    plotXAxis minMax(0), Array(graphLeft,graphTop+graphHeight-10,graphWidth+graphLeft,graphTop+graphHeight+10 _
		,positioning), """black""", XAxisTitle, barX, stringValueArray
  end if
  if not isnull(YAxisTitle) Then
	stringvalueArray = Empty
    if Typename(dataArray(0)(yIndex))="String" Then stringValueArray = DifferentValuesInColumn(dataArray,yIndex)
    'Response.Write "ZX: yIndex = " & yIndex & "<BR>" & vbCrlf
    plotYAxis minMax(1), Array(graphLeft-10,graphHeight+graphTop,graphLeft+10,graphTop,positioning) _
		, "black", YAxisTitle, barY, stringValueArray
  end if

  for each xIndex in xIndexArray
    rescaleColumnsOfArray  Array(xIndex), Array(graphLeft), Array(graphWidth+graphLeft), dataArray _
	  , Array(minMax(0))
  next
  xIndex = xIndexArray(0)
	  
  for each yIndex in yIndexArray
    rescaleColumnsOfArray Array(yIndex), Array(graphHeight+graphTop), Array(graphTop), dataArray _
	  , Array(minMax(1))
  next
  yIndex = yIndexArray(0)


end function

function lineGraphSeries(byval dataArray _
	, byval columnArray, byval columnValueArray _
	, byval xIndex, byval yIndex, byval seriesName, byval colorExpr, byval positioning)
	filteredArray dataArray, columnArray, columnValueArray
	if not isempty(dataArray) Then
	  plotXYLineSeries  xIndex, yIndex, dataArray, colorExpr, 2, positioning
	End If
end function

function getMinimumDifferenceForColumn(dataArray, xAxisColumn)
  '
  'Get minimum distance between X values 
  '  
  Dim xDistance
  Dim isdiffFound
  dim rowIndex
  isDiffFound = false
  if isempty(dataArray) then
    xDistance = Null
  Elseif typename(dataArray(lbound(dataArray))(xAxisColumn))="String" then
    xDistance = 1
  else
    xDistance = 0
    mergeSortEntireArray dataArray, Array(xAxisColumn)
    For rowIndex = lbound(dataArray) + 1 to ubound(dataArray)
      Dim diff
      diff = dataArray(rowIndex)(xAxiscolumn) - dataArray(rowIndex-1)(xAxisColumn)
      if 0 <diff And (diff<xDistance Or (not isdiffFound)) Then
        isDiffFound = True
        xDistance = diff
      end if
    next
  End If
  getMinimumDifferenceForColumn = xDistance
end function

function writeSeriesLabel(seriesIndex, color, seriesName, positioning, x, y, attrExpr, layerExpr _
	, thisRow)
  dim attr, layerAttr
  if ""<attrExpr then attr=eval(attrExpr)
  if ""<layerExpr then layerattr=eval(layerExpr)  

  '
  'Todo: a problem here is that we don't want to offset images in attrEpxr and layerExpr.
  '      We'd like to display the entire image, scaled to fit the series label box.
  '
	  if 0<instr(attr,"<") then attr=""
	  plotBlock Array(x,y+SeriesIndex*graphSeriesBoxYSpace) _
		, Array(x+graphSeriesBoxWidth,y+graphSeriesBoxHeight+SeriesIndex*graphSeriesBoxYSpace) _
		, positioning, color, attr, "", layerAttr
	  plotPositionStart x+graphSeriesBoxXSpace+5,y+5+SeriesIndex*graphSeriesBoxYSpace, positioning, ""
	    Response.Write Replace(server.HTMLEncode(seriesName)," ","&nbsp;")
	    plotPositionEnd positioning
end function

function safemod(x,y)
  safemod = (x+y) mod y
end function

function defaultColorForIndex(index)
  Dim defaultColorArray
  defaultColorArray = Array("red","green","blue","purple","black","grey","brown","yellow")
  defaultColorForIndex = defaultColorArray(safemod(index-1, (ubound(defaultColorArray)+1)))
end function

'
'Module:        includearray.asp
'Description:   Standard array inclusion script for Fault Tracking site
'Author:        James Barbetti, 01-Sep-2000 to ?
'History:       First draft, 01-Sep-2000 (stub only)
'				26-Sep-2000 moved DumpArrayOfArrays and
'				DumpArrayOfArraysAsTable here (they were in 
'				includeMergesort.asp).
'				14-Nov-2000 added explanatory comments
'

Public Function isElementInArray(byval AmI, byref inMe)
  Dim index
  Dim result 
  result = false
  if not isempty(inMe) Then
    for index = lbound(inMe) to ubound(inMe)
      if inMe(index) = amI Then
        result = true
        exit for
      end if
    next
  end if
  isElementInArray = result
End Function

Public Function AddElementsToArray(byval addThese, byref toThis)
  dim inputIndex
  dim outputIndex
  if isempty(addThese) Then
    'Nothing to add    
  elseif isempty(toThis) Then
    toThis = addThese
  else
    outputIndex = ubound(toThis) 
    redim preserve toThis(ubound(toThis) + ubound(addThese) - lbound(addThese) + 1)
    for inputIndex = lbound(addThese) to ubound(addThese)
      outputIndex = outputIndex + 1
      if isObject(addThese(inputIndex)) Then
        set toThis(outputIndex) = addThese(inputIndex)
      else
        toThis(outputIndex) = addThese(inputIndex)
      end if
    next
  end if
end Function

Public Function AddElementToArray(byval addMe,byref toMe)
  '
  'Description:	Adds an element to an array
  '
  If isempty(toMe) Then
    Redim toMe(0)
  Else
    Redim Preserve toMe(ubound(toMe)+1)
  End If
  if isobject(addMe) Then
    Set Tome(ubound(Tome)) = AddMe
  else
    ToMe(ubound(ToMe)) = addMe
  end if
End Function

Public Function ReverseArray(byref reverseMe)
  '
  'Description:	Reverses the order of elements in an array
  '
  If Not isempty(reverseMe) Then
    Dim newCopy
    Dim i
    Redim newCopy(ubound(reverseMe))
    for i = 0 to ubound(reverseMe)
	  if IsObject(reverseMe(i)) Then
        Set newCopy(ubound(reverseMe) - i) = reverseMe( i )       
      else
        newCopy(ubound(reverseMe) - i) = reverseMe( i )       
      end if
    Next
    reverseMe = newCopy
  End If
end Function

Public Function countElements(byref ofArray)
  '
  'Description:	Returns the count of elements in an array
  '
  if isempty(ofArray) Then
    countElements = 0
  else
    countElements = ubound(ofArray) + 1
  End If
End Function

Public Function DumpArrayOfArrays(byval DumpMe, byval RowHeader, byval RowFooter _
	, byval ColHeader, byval colFooter, byval EncodeForHTML)
	'
	'Description:	Dumps out a description of the contents of an array
	'				of arrays (diagnostic function).
	'Parameters:	dumpMe			-	array to dump
	'				rowHeader		-	HTML to put at front of each row
	'				rowFooter		-	HTML to put after each row
	'				colHeader		-	HTML to put at the front of each column
	'				colFooter		-   HTML to put after each column
	'				encodeForHTML	-	True to Server.HTMLEncode each element,
	'									false not to.
	'Notes:			If you're in a hurry, use DumpArrayOfArraysAsTable.
	'
	dim lngRowIndex
	Dim lngColIndex
	Dim val
	
	If Not isempty(DumpMe) Then
		For lngRowIndex = lbound(DumpMe) to ubound(DumpMe)
			For lngColIndex = lbound(DumpMe(lngRowIndex)) to ubound(DumpMe(lngRowIndex))
				val = DumpMe(lngRowIndex)(lngColIndex)
				Select case TypeName(val)
					Case "Null"
						DumpMe(lngRowIndex)(lngColIndex)="*Null*"
					Case "Empty"
						DumpMe(lngRowIndex)(lngColIndex)="*Empty*"
					Case else
						If EncodeForHTML Then
						  DumpMe(lngRowIndex)(lngColIndex)=Server.HTMLEncode(cstr(val))
						else
						  DumpMe(lngRowIndex)(lngColIndex)=cstr(val)
						End If
				End Select				
			Next
			Response.Write RowHeader
			Response.Write ColHeader _
				+ Join(DumpMe(lngRowIndex), ColFooter + ColHeader) _
				+ ColFooter
			Response.Write RowFooter
		Next
	End if
End Function

Public Function DumpArrayOfArraysAsTable (byval TestResult, byval IndentLevel _
	, byval EncodeForHTML)
  Response.WRite space(indentLevel) & "<TABLE>" & vbCrlf
  DumpArrayOfArrays TestResult, space(indentLevel) & "  <TR>" & vbcrlf, "  </TR>" & vbCrlf _
	, space(indentLevel) & "    <TD>", "</TD>" & vbCrlf, EncodeForHTML
  Response.Write space(indentLevel) & "</TABLE>" & vbcrlf
End Function

Public function extractRecordsetDataToArrayOfArrays(byval thisRS, byref rowDataArray)
  Dim columnArray
  Redim columnArray(thisRS.Fields.Count-1)
  IF (0 < thisRS.RecordCount) Or (thisRS.RecordCount = -1) Then         
	While (not thisRS.EOF) And Response.IsClientConnected 
	  For columnIndex = 0 to thisRS.Fields.Count-1
	    columnArray(columnIndex) = thisRS.Fields(columnIndex).Value
	  Next
	  addElementToArray columnArray, rowDataArray
	  thisRS.MoveNext
	Wend
  End If
end function


'
'Module:	includeMergesort.asp
'

Private Sub RedimensionArray(ByVal hibound  _
    , ByVal PreserveData, ByRef Target)
    '
    'Description:	Routine for redimensioning an array.
    'Explanation:	This cannot always be done with a Redim
    '				statement.  Consider, for example, 
    '				redimensioning each array in an array
    '				of arrays.
    '				In your outer loop you might have
    '				outerArray - the array of arrays
    '				i		   - index into that array.
    '				But how do you change the dimension
    '				of outerArray(i)...?
    '				You can't use
    '
    '				Redim Preserve outerArray(i)(newBound)
    '				
    '				as that is not syntactically valid.
    '				Hence this routine, which allows:
    '
    '				RedimensionArray newBound,true _
    '					outerArray(i)
    '
    If PreserveData Then
        ReDim Preserve Target(hibound)
    Else
        ReDim Target(hibound)
    End If
End Sub

Private Function CreateIndexArray(ByVal lowbound _
    , ByVal Highbound , ByRef Here)
    '
    'Description:	Creates an array which contains
    '				all the indices in a specified
    '				range.
    'Example:		CreateIndexArray(0,4,x)
    '				is equivalent to 
    '				x = Array(0,1,2,3,4).
    'Explanation:	The sorting routines in this module
    '				do not swap the actual array rows
    '				when they are determining the correct
    '				order for the sorted array.  They
    '				swap indices INTO the array.
    '				Swapping the indices is faster for
    '				all but the smallest arrays.
    '
    Dim Index 
    RedimensionArray Highbound-lowBound, False, Here
    For Index = lowbound To Highbound
        Here(Index) = Index
    Next
End Function

Private Sub CopyElements(byval FirstIndex, byval LastIndex _
	, byref SourceArray, byref TargetArray)
	'
	'Description:	Copy elements between two arrays
	'				starting at FirstIndex and finishing
	'				at LastIndex.
	'Notes:			This routine exists only because
	'				there's a *much* faster way to execute
	'				long copies in VB, and these routines
	'				were copied out of a VB component.
	'
	Dim Index
	For Index=FirstIndex To LastIndex
		TargetArray(Index) = SourceArray(Index)
	Next
End Sub

Private Function Comparerows(ByRef SortMe  _
    , ByVal row1, ByVal row2 , ByRef SortKey )
    '
    'Description:	Compares two rows of the same array of
    '				arrays (their indices supplied by row1
    '				and row2), according to a sort key
    '				(which may include any number of columns).
    'Example:		If...
    '
    '				a = array(array("cat",4),array("dog",4))
    '				
    '				and you call
    '
    '				CompareRows(0,1,a,Array(1,0))
    '
    '				it will return -1, because the values in
    '				rows 0 and 1 for column 1 match, but
    '				the value in row 0 for column 0 is <
    '				the value in row 1.
    'Notes:			Null comparison semantics are honoured.
    '				This has a serious performance cost,
    '				unfortunately.  However, without it,
    '				a Mergesort	may give the wrong answer.
    '
    Dim Diff		'The sign of the difference of the most
					'recent column comparison (-1,0 or 1)
    Dim Index		'The index into the sort key
    Dim field1		'The value from row1 for the current column
    Dim field2		'The value from row2 for the current column
    Dim sortIndex	'The index of the next column to compare
    Dim desc		'Will be 1 if ascending, -1 if descending
    
    Diff = 0
    Index = LBound(SortKey)
    While Index <= UBound(SortKey) And Diff = 0
		sortIndex = SortKey(Index)
		If 0<instr(ucase(sortIndex), "DESC") Then
		  sortIndex = Cint(left(sortIndex,len(sortIndex)-5))
		  desc = -1
		else
		  desc = 1
		End If
        field1 = SortMe(row1)(sortIndex)
        field2 = SortMe(row2)(Sortindex)
        Diff = CompareVariants(field1, field2) * desc
        If Diff = 0 Then
            Index = Index + 1
        End If
    Wend
    Comparerows = Diff
End Function

Public Function CompareVariants(ByVal Try1 , ByVal Try2 ) 
	'
	'Description:	Compares two variants, Try1 and Try2
	'				and returns -1 if Try1 belongs before
	'				Try2, 0 if they are equal, and 1 if
	'				Try1 belongs after Try2 (in an
	'				ascending order).
	'Notes:			String comparisons are case
	'				insensitive.
	'				ANSI Null comparison rules are honoured.
	'				Null is considered to come LAST.
	'
    Dim Diff 
    If typename(try1) = "String" And typename(try2) = "String" Then
	  'All string comparisons are case insensitive
      try1 = ucase(try1)
      try2 = ucase(try2)
    End If
    If IsNull(Try2) Then
        If IsNull(Try1) Then
            Diff = 0
        Else
            Diff = -1
        End If
    ElseIf IsNull(Try1) Then
        Diff = 1
    ElseIf Try1 < Try2 Then
        Diff = -1
    ElseIf Try2 < Try1 Then
        Diff = 1
    Else
        Diff = 0
    End If
    CompareVariants = Diff
End Function

Private Sub TwoWayMergeSubArrays(ByRef SortKey, ByRef SortMe  _
    , ByVal Low1 , ByVal High1 , ByRef IndexArray1  _
    , ByVal Low2 , ByVal High2 , ByRef IndexArray2  _
    , ByVal LowOut , ByRef IndexArrayOut )
    '
    'Description:   Straight linear merge of two subarrays
    'Parameters:    SortKey - comparison key
    '               SortMe  - array to sort
    '               IndexArray1, Low1, High1
    '                   The array which contains the indices of the first subarray
    '                   to merge.
    '               IndexArray2, Low2, High2
    '                   The array which contains the indices of the second subarray
    '                   to merge. IndexArray2 and IndexArray1 *may* be the same.
    '               IndexArrayOut, LowOut
    '                   The array into which the result of the merge is to be written.
    '                   Must NOT be the same as IndexArray1 or IndexArray2, *unless*
    '                   there is no overlap between
    '                   (LowOut , LowOut + (High1-Low1) + (High2-Low2) + 1)
    '                   and
    '                   (Low1, High1) - if IndexArrayOut = IndexArray1
    '                   and/or
    '                   (Low2, High2) - if IndexArrayOut = IndexArray2.
    'Notes:         This routine is *not* appropriate for arrays where the data
    '               are known to be clumpy.  Nor is it appropriate when one of
    '               the subarrays to be merged is *much* larger than the other.
    '
    Dim Diff 
    Dim Index1 
    Dim Index2 
    Dim IndexOut 
    
    Index1 = Low1
    Index2 = Low2
    IndexOut = LowOut
    
    While (Index1 <= High1) And (Index2 <= High2)
        Diff = Comparerows(SortMe, IndexArray1(Index1), IndexArray2(Index2), SortKey)
        If Diff <= 0 Then
            IndexArrayOut(IndexOut) = IndexArray1(Index1)
            Index1 = Index1 + 1
        Else
            IndexArrayOut(IndexOut) = IndexArray2(Index2)
            Index2 = Index2 + 1
        End If
        IndexOut = IndexOut + 1
    Wend
    
    For Index1 = Index1 To High1 
		IndexArrayOut(IndexOut) = IndexArray1(Index1)
		IndexOut = IndexOut + 1
    Next
    
    For Index2 = Index2 to High2 
		IndexArrayOut(IndexOut) = IndexArray2(Index2)
		IndexOut = IndexOut + 1
    Next    
End Sub

Private Function ReorderTargetByRef(ByRef SortOrder  _
    , ByRef SortMeByRef  _
    , ByVal UpperBound)
    '
    'Description:	Reorder an array according to a sort order
    '				determined by a sorting algorithm (in this
    '				case, Mergesort, but it could as easily
    '				be Quicksort or Heapsort).
    'Notes:         Similar in some respects to the ReorderArray routine in modQuicksort.bas
    '               but with extra parameters (for greater flexibility in deciding how to
    '               call it). 
    '
    Dim Sorted 
    Dim Index 
    If Not IsEmpty(SortMeByRef) Then
        RedimensionArray UpperBound _
            ,  False, Sorted
        For Index = LBound(SortOrder) To UpperBound
            If IsObject(SortMeByRef(SortOrder(Index))) Then
                Set Sorted(Index) = SortMeByRef(SortOrder(Index))
            Else
                Sorted(Index) = SortMeByRef(SortOrder(Index))
            End If
        Next
        ReorderTargetByRef = Sorted
    End If
End Function

Public Sub mergeSortEntireArray(byref SortMe, byref SortKey)
  if not isempty(sortMe) Then
    SimpleMergeSortArrayOfArrays SortMe, SortKey, lbound(SortMe), ubound(SortMe)
  end If
end Sub

Public Sub SimpleMergeSortArrayOfArrays (ByRef SortMe, byref SortKey  _
    , LowerBound , UpperBound)
	'
	'Description:	Routine for carrying out a straight merge 
	'				on a portion of an array.
	'Notes:			Most examples of merging sorts use
	'				recursion.  But for a straight merge,
	'				this is not necessary.  It is possible
	'				to write a strictly iterative straight
	'				merge and that is what has been done here.
    'Explanation:	A straight merge works by combining
    '				("merging") adjacent sections of
	'				approximately equal size, already known
	'				to be in order.  The first merge works
	'				for 2 elements at a time.  The next
	'				pass merges adjacent 2-element groups 
	'				into 4-element sorted subgroups, and
	'				so on.
	'				According to the textbooks, Mergesort is
	'				slower than Quicksort.  However, a
	'				straight mergesort requires fewer row
	'				comparisons (though it does more row
	'				swaps, on average), and does NOT have the
	'				same performance problem as Quicksort 
	'				when sorting ordered or almost-ordered 
	'				data.
	'				

    Dim StepSize 
    Dim IndexArray1 
    Dim IndexArray2 
    Dim Start                
    Dim blnInFirstArray 
    
    If not isempty(SortMe) then        
        StepSize = 1
        CreateIndexArray LBound(SortMe), UpperBound, IndexArray1
        IndexArray2 = IndexArray1
        While StepSize * 2 <= UpperBound - LowerBound + 1
            For Start = LowerBound To UpperBound - StepSize * 2 + 1 Step StepSize * 2
                TwoWayMergeSubArrays SortKey, SortMe, Start, Start + StepSize - 1, IndexArray1 _
                    , Start + StepSize, Start + StepSize * 2 - 1, IndexArray1 _
                    , Start, IndexArray2
            Next
            If Start <= UpperBound Then
                CopyElements Start - StepSize * 2, Start - 1, IndexArray2, IndexArray1
                TwoWayMergeSubArrays SortKey, SortMe, Start - StepSize * 2, Start - 1, IndexArray1 _
                    , Start, UpperBound, IndexArray1, Start - StepSize * 2, IndexArray2
            End If
            blnInFirstArray = False

            StepSize = StepSize * 2
            If StepSize * 2 <= UpperBound - LowerBound + 1 Then
                For Start = LowerBound To UpperBound - StepSize * 2 + 1 Step StepSize * 2
                    TwoWayMergeSubArrays SortKey, SortMe, Start, Start + StepSize - 1, IndexArray2 _
                        , Start + StepSize, Start + StepSize * 2 - 1, IndexArray2 _
                        , Start, IndexArray1
                Next
                If Start <= UpperBound Then
                    CopyElements Start - StepSize * 2, Start - 1, IndexArray1, IndexArray2
                    TwoWayMergeSubArrays SortKey, SortMe, Start - StepSize * 2, Start - 1, IndexArray2 _
                        , Start, UpperBound, IndexArray2, Start - StepSize * 2, IndexArray1
                End If
                blnInFirstArray = True
                StepSize = StepSize * 2
            End If
        Wend
            
        If blnInFirstArray Then
			'Response.Write Join(IndexArray1,",")
            SortMe = ReorderTargetByRef (IndexArray1, SortMe, UpperBound)
        Else
			'Response.Write Join(IndexArray2,",")
            SortMe = ReorderTargetByRef(IndexArray2, SortMe, UpperBound)
        End If
    End If
End Sub

Public Function binaryLookup(byval val, byref ThisArray _
	, byval searchColumnIndex, byval extractColumnIndex)
  Dim lo
  Dim hi
  DIm try
  Dim diff
  lo = lbound(ThisArray)
  hi = ubound(ThisArray)
  While lo <= hi
    try = int((lo + hi ) / 2)
    diff = CompareVariants( val, ThisArray(try)(searchColumnIndex))
    if diff < 0 Then 
      hi = try-1
    ElseIf 0 < diff Then 
      lo = try+1
    Else 
      binaryLookup = ThisArray(try)(extractColumnIndex)
      Exit Function
    End If
  Wend 
  binaryLookup = ""
End Function


'Module:		includeReport.asp

sub writeReportHeaderToResponse(title)
  '
  'Description:	Writes a report header.  Also sets <TH> and <TD> styles
  '				with an inline stylesheet.
  'Notes:		Because the bar and line graphing routines use unclassed
  '				table cells, the standard "report numbers" stylesheet 
  '				doesn't work correctly when graphing.  Use
  '				writeStylelessReportHeaderToResponse instead for graphs.
  '
%>
<HTML>
<HEAD>
<META HTTP-EQUIV="Content-Type" CONTENT="text/html; charset=windows-1252">
<TITLE><%=Server.HTMLEncode(Title)%></TITLE>
</HEAD>
<BODY LEFTMARGIN="30" TOPMARGIN="30" MARGINWIDTH="30" MARGINHEIGHT="30">
<%end sub

sub writeReportFooterToResponse()%>
</BODY>
</HTML>
<%end sub%>