Fountain and Gazebo

// (c) Robert J Becraft, All Rights Reserved.
#declare Water=texture {
pigment { color rgb< 0.0, 0.1, 0.2 > }
normal { bumps 0.1 scale < .25, 0.15, 0.15 > }
finish { phong 1 reflection 0.5 ambient 0.1 diffuse 0.2 }
}

#declare Pillar=union{
cone{<0,0,0> .2 <0,3,0> .15}
cylinder{<0,0,0><0,.1,0> .25}
cylinder{<0,3,0><0,3.1,0> .2}
} 


#declare Fountain=union{ 
difference{ 
union{
cylinder{<0,.2,15><0,.25,15> 6}
cylinder{<0,.2,-15><0,.25,-15> 6}
box{<-6,.2,-15><6,.25,15> }
cylinder{<0,0,15><0,.2,15> 5.98 texture{T_GrayBrick scale .0325}}
cylinder{<0,0,-15><0,.2,-15> 5.98 texture{T_GrayBrick scale .0325}}
box{<-5.98,0,-15><5.98,.2,15> texture{T_GrayBrick scale .0325}} 
}
union{
cylinder{<0,0,15><0,.251,15> 5.5}
cylinder{<0,0,-15><0,.251,-15> 5.5}
box{<-5.5,0,-15><5.5,.251,15> }
} 
texture{T_Stone8}
} // difference
union{
cylinder{<0,0,15><0,.15,15> 5.5}
cylinder{<0,0,-15><0,.15,-15> 5.5}
box{<-5.5,0,-15><5.5,.15,15> }
texture{Water }
} 
cylinder{<0,0,0><0,.5,0> 2 texture{T_Stone8}}
cylinder{<0,.5,0><0,.6,0> 2.2 texture{T_Stone8}}
#declare C=0;
#while(C<360)
object{Pillar translate<1.8,.6,0> rotate<0,C,0> texture{T_Stone5}}
#declare C=C+30;
#end
cylinder{<0,3.6,0><0,3.7,0> 2.2 texture{T_Stone8}}
cylinder{<0,3.7,0><0,4.2,0> 2 texture{T_Stone5}}
cylinder{<0,4.2,0><0,4.3,0> 2.2 texture{T_Stone8}}
difference{
union{
sphere{<0,4.3,0> 2 texture{T_Stone8}}
#declare CR=0;
#while (CR<180)
cylinder{<-.05,4.3,0><.05,4.3,0> 2.05 texture{T_Stone8} rotate<0,CR,0>}
#declare CR=CR+45;
#end
}// union 
box{<-2.15,2.2,-2.15><2.15,4.2,2.15>} 
}
cylinder{<0,6.2,0><0,6.5,0> .3 texture{T_Stone8}}
cylinder{<0,6.5,0><0,6.7,0> .4 texture{T_Stone8}}
sphere{<0,6.7,0> .35 texture{T_Stone8}}
sphere{<0,7.2,0> .15 texture{T_Stone5}}
cone{<0,7.35,0> .05 <0,8.8,0> .001 texture{T_Stone8}} 

} // Fountain