Flower6.inc

//(c) Robert J Becraft.  All Rights Reserved.
#declare S1=seed(383);
#declare Petal6=union{ // pansy-like flower
  cylinder{<0,0,0><0,.0001,0> .008 translate<-.0025,0,-.0015>}
  cylinder{<0,0,0><0,.0001,0> .008 translate<.0025,0,-.0015>}
  box{<-.0012,0,-.0012><.0012,.0001,.0012> rotate<0,45,0> scale<.75,1,1.5>}
} 
#declare Flower6=union{
  #declare Count=1;
  #while (Count<150)
      #declare ZR=rand(S1)*-45;
      #declare YR=rand(S1)*360;
      #declare X=rand(S1)*.0065;
      union{
         cylinder{<0,0,0><0,.005,0> .0001}
         sphere{<0,.005,0> .0002}
                    texture{pigment{color Orange1}}
                    rotate<0,0,ZR> 
                    translate<X,0,0> 
                    rotate<0,YR,0> 
                  }
         #declare Count=Count+1;
  #end
  sphere{<0,0,0> .005 scale <1,.5,1> translate<0,-.005,0>
       texture{pigment{color DarkGreen}}}
  cone{<0,0,0> .005 <0,-.018,0> .0035 texture{pigment{color DarkGreen}}}
  sphere{<0,-.018,0> .0035 texture{pigment{color DarkGreen}}}

  #declare Count=0;
  #while (Count<360)
     #declare Y1=rand(S1)*-.0025;
     #declare ZS=rand(S1)*1+.25;
     #declare XS=rand(S1)*.25+.25; 
     #declare ZR=rand(S1)*25;
     #declare XR=rand(S1)*-50+40;
     #declare CO=int(rand(S1)*6)+1;
     object{Petal6 
              normal {wrinkles .0000050} 
              translate<0,Y1,-.01>
              rotate<0,0,ZR>
              scale <1,1,ZS> rotate<XR,Count,0> 
             #switch (CO)
                 #case (1) texture{pigment{color LightBlue}}#break
                 #case (2) texture{pigment{color LightBlue}}#break
                 #case (3) texture{pigment{color LightBlue1}}#break
                 #case (4) texture{pigment{color LightBlue2}}#break
                 #case (5) texture{pigment{color LightBlue3}}#break
                 #case (6) texture{pigment{color LightBlue4}} #break 
              #end 
            } 
      #declare Count=Count+rand(S1)*10+75;
  #end
}