My WoW Backup
Script
This is the script that I use for backing up my WoW UI, I
then copy the
zip file off the desktop on to a thumb drive to carry with me.
The script is available for download here
(SHA1SUM
e3c5c4033d5e857610eecf92597e2291a725e92e).
It relies on 7-Zip, available for free from http://www.7-zip.org.
Source: backup-wow.bat
@echo off
REM WoW Backup Script
REM v1.3a
REM
REM Requires 7-zip from http://www.7-zip.org/
REM
REM Tailor the BOPTS variable to your needs, I use Ace so I have an extra ace directory.
REM The base directories are: Interface Logs Screenshots WTF
REM REM v1 - Original
REM v1.1 - Fixed hour, so that " 7" is now "07"
REM v1.2 - took out recursive, when files are specified -r got ALL of WoW
REM v1.3 - Excluded config.wtf (overwriting machine specific settings
REM like Gamma and Resolution). Copy current config to hostname-.
REM REM Set the Directory WoW is in (must be in quotes if white space used)
set WOWD="C:\Program Files\World of Warcraft"
REM Set the things to backup (any white space must be in quotes)
set BOPTS="WoW - AboveNormal Priority.bat" backup-wow.bat Interface Logs Screenshots WTF dm ace
REM This variable defines where the archive goes
set DEST=C:\Documents and Settings\%USERNAME%\Desktop
REM This Variables defines the backup prefix
set BPRE=WoWIntrFull-2010
REM This variable defines where 7zip is (must be in quotes if white space used)
set ZIP="C:\Program Files\7-zip\7z.exe"
REM This Variable defines the command options to use
set ZCMD=a -tzip -x!wtf\config.wtf
REM This function defines the backup suffix (mon-day-year_hourminutesecmsec)
set hour=%time:~0,2%
if "%hour:~0,1%"==" " set hour=0%time:~1,1%
set BSUF=%date:~4,2%-%date:~7,2%-%date:~10,4%_%hour%%time:~3,2%%time:~6,2%%time:~9,2%
REM Combine Prefix, Suffix, and Extention (Ex. WoWIntrFull-06-15-2006_07312917.zip)
set FNAM=%BPRE%-%BSUF%.zip
echo action
copy /v /y %WOWD%\WTF\Config.wtf %WOWD%\WTF\%COMPUTERNAME%-config.wtf
cd %WOWD%
%ZIP% %ZCMD% "%DEST%\%FNAM%" %BOPTS%
