|
أمر السكرامبل التلقائي
قم بنسخ الاوامر الموجودة في الصندوق السفلي و ضعها في ملف جديد في الرموت
يمكن بعد ذلك التحكم باللعبة عن طريق القائمة (البوب ابس) الموجودة في الجنل
لا تنسى أن تتأكد من الرموت في وضع تشغيل
كذلك تأكد بألا تضع أي أسطر خالية في الملف الذي يحتوي على الأسألة و الأجوبة
menu channel {
اوتو سكرامبل
.تشغيل:{
if ($me ison %as.chan) {
echo $color(info) -a * الرجاء ايقاف اللعبة اولا ثم حاول تشغليها مرة اخرى
}
else {
if ($server) {
%as.chan = $chan
%as.q = 1
_nextquestion
}
else {
echo $color(info) -a * عفوا، يجب أن تشبك على سيرفر قبل تشغيل اللعبة
}
}
}
.إيقاف:{
if ($?!="هل أنت متأكد؟") { unset %as.* %asp.* | echo $color(info) -a * تم إيقاف اللعبة }
}
.السؤال التالي:if ($server) && ($me ison %as.chan) { _nextquestion }
.-
.الأسألة:{
if ($exists(asquestions.txt)) { run asquestions.txt }
else {
write -c asquestions.txt
write asquestions.txt Countries [الكويت]
write asquestions.txt Counrties [السعودية]
write asquestions.txt Counrties [البحرين]
write asquestions.txt Counrties [قطر]
write asquestions.txt Counrties [الامارات]
write asquestions.txt Counrties [عمان]
run asquestions.txt
}
}
}
on *:TEXT:%as.a:%as.chan:{
if (%as.s) {
unset %as.s
inc %asp. [ $+ [ $site ] ]
msg $chan Correct answer $nick $+ . Points: %asp. [ $+ [ $site ] ] - Next question in 10 seconds
.timer 1 10 _nextquestion
}
}
alias _nextquestion {
if ($server) && ($me ison %as.chan) {
if (%as.q !isnum 0-) {
%as.q = 0
}
inc %as.q
var %r = $read(asquestions.txt,%as.q)
if (%r) {
var %[ = $numtok(%r,91)
var %t = 1- $+ $calc(%[ - 1)
var %q = $gettok(%r,%t,91)
%as.a = $gettok($gettok(%r,%[,91),1,93)
%as.s = 1
msg %as.chan $chr(2) $+ أوتو سكرامبل
msg %as.chan $chr(2) $+ [السـؤال] $+ $chr(15) %q
msg %as.chan $chr(2) $+ [الإجابـة] $+ $chr(15) $_scrambled2(%as.a)
}
else {
if (%as.q != 1) {
%as.q = 1
_nextquestion
}
}
}
}
alias _scrambled2 {
var %_words = 1
while (%_words <= $numtok($1-,32)) {
var %_scrwords = %_scrwords $_scramd2($gettok($1-,%_words,32))
inc %_words
}
return %_scrwords
}
alias _scramd2 {
if ($1 == $null) { return }
var %actext = $1
var %numberofchars = $len($1)
while (%numberofchars) {
var %randomchar = $r(1,%numberofchars)
var %scramdans = %scramdans $+ $mid(%actext,%randomchar,1)
var %actext = $left(%actext,$calc(%randomchar - 1)) $+ $right(%actext,$calc($len(%actext) - %randomchar))
dec %numberofchars
}
return %scramdans
}
|
أي استفسار؟
goblin@arabchat.org
العودة إلى الصفحة الرئيسية
|
