* ======================================================================= 
*  File:  	read data from mixed file.SPS .
*  Date:  	9-Oct-2005 .
*  Author:  	Bruce Weaver, bweaver@lakeheadu.ca .
*  Notes:	Examples of reading input from a mixed (text) file .
* ======================================================================= .

* This example uses the FILE TYPE--END FILE TYPE command.
* Based on http://www.jrsa.org/ibrrc/extracting_data/reading_code.sps .

* Data file looks like this (but without the *):

*01bwm18051960
*0234245
*03abcdef           .

* There are three record types, 01, 02, and 03.
* These are read in as strings, and assigned to variable RECTYPE.

* Use macro to define path to folder in which data file is stored .

DEFINE !dpath()'C:\bw\SPSS\data\'!ENDDEFINE.	/* <----- Modify this to indicate the data folder on your PC .

* -------------------------------------------------- .
* Example 1:  Read all 3 record types into one file.
* -------------------------------------------------- .

file type mixed file = !dpath + 'mixed data file.txt'
  record = rectype 1-2 (a).

Record type '01'.
data list /
   init 3-4 (a)
   sex 5-5 (a)
   dobday 6-7
   dobmth 8-9
   dobyr 10-13 .

Record type '02'.
data list /
   q1 3
   q2 4
   q3 5
   q4 6
   q5 7 .

Record type '03'.
data list /
   letter1 3 (a)
   letter2 4 (a)
   letter3 5 (a)
   letter4 6 (a)
   letter5 7 (a)
   letter6 8 (a) .
end file type.
exe.

list.

* -------------------------------------------------- .
* Example 2:  Read 1 record type at a time.
* -------------------------------------------------- .

file type mixed file = !dpath + 'mixed data file.txt'
  record = rectype 1-2 (a).

Record type '01'.
data list /
   init 3-4 (a)
   sex 5-5 (a)
   dobday 6-7
   dobmth 8-9
   dobyr 10-13 .
end file type.
exe.

list.

file type mixed file = !dpath + 'mixed data file.txt'
  record = rectype 1-2 (a).

Record type '02'.
data list /
   q1 3
   q2 4
   q3 5
   q4 6
   q5 7 .
end file type.
exe.

list.

file type mixed file = !dpath + 'mixed data file.txt'
  record = rectype 1-2 (a).

Record type '03'.
data list /
   letter1 3 (a)
   letter2 4 (a)
   letter3 5 (a)
   letter4 6 (a)
   letter5 7 (a)
   letter6 8 (a) .
end file type.
exe.

list.

* ======================================================================= .