*  ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~ 
   File:  	change_scores_and_ANCOVA.SPS 
   Date:  	21-Jan-2002
   Author:  Bruce Weaver, weaverb@mcmaster.ca 
   Notes:	Analysis of change scores.
*  ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~ .

* Data from Table 17-1 in "Biostatistics: The Bare Essentials" (2nd ed),
   by Norman & Streiner (2000).

DATA LIST free /grp pre post .
BEGIN DATA.
1 22 16
1 24 17
1 32 25
1 24 21
1 35 32
1 27 22
1 34 27
1 15 13
1 29 25
1 25 21
2 32 31
2 33 34
2 42 34
2 27 24
2 22 24
2 18 15
2 16 13
2 32 29
2 25 19
2 24 22
END DATA.

compute change = post - pre.
exe.
format grp (f2.0) / pre post change (f5.0).
means pre post change by grp.

GRAPH
  /SCATTERPLOT(BIVAR)=pre WITH post BY grp
  /MISSING=LISTWISE
  /TITLE= 'Title Here'.

* Independent groups t-test on change score (p. 155 in Bare Essentials, 2nd Ed) .

T-TEST
  GROUPS=grp(1 2)
  /MISSING=ANALYSIS
  /VARIABLES=change
  /CRITERIA=CIN(.95) .

* Mixed design (between-within) ANOVA (p. 156).

GLM
  pre post BY grp
  /WSFACTOR = time 2 Polynomial
  /METHOD = SSTYPE(3)
  /CRITERIA = ALPHA(.05)
  /WSDESIGN = time
  /DESIGN = grp .

* ANCOVA with DV = post, covariate = pre .

UNIANOVA
  post  BY grp  WITH pre
  /METHOD = SSTYPE(3)
  /INTERCEPT = INCLUDE
  /CRITERIA = ALPHA(.05)
  /print = parameter
  /emmeans = table(grp)
  /DESIGN = pre grp .

* NOTE:  b = 0.885 for the PRE-TEST score in this model .

* In September 2001, Paolo Morelli posted a question to one of the sci.stat
   newsgroups, asking if it would be okay to use the CHANGE score as the 
   DV while including the PRE-TEST score as a covariate.

* In his response, Jerry Dallal said it would be "convoluted, but not wrong".

* Run model with DV = change, covariate = Pre-Test score.

UNIANOVA
  change  BY grp  WITH pre
  /METHOD = SSTYPE(3)
  /INTERCEPT = INCLUDE
  /CRITERIA = ALPHA(.05)
  /print = parameter
  /emmeans = table(grp)
  /DESIGN = pre grp .

* NOTE:  	Compared to the previous model, the only thing that changes is
		 the parameter for PRE-TEST; the other parameters are identical,
		 as is the F-test for GROUP .

*		The parameter (b) for PRE-TEST in this second model = the
		 same parameter in the first model minus 1.

*		So, what's all the fuss about when folks want to analyze
		 change scores and include a pre-test as a covariate?  If
		 the question of interest is whether or not there is a 
		 difference between groups, you get the same result as you
		 do with the POST-TEST score as the DV .

*  ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~ .

* Correlation matrices & scatterplots .

CORRELATIONS
  /VARIABLES=pre post change
  /PRINT=TWOTAIL NOSIG
  /MISSING=PAIRWISE .

GRAPH
  /SCATTERPLOT(BIVAR)=pre WITH post by grp
  /MISSING=LISTWISE
  /TITLE= 'Pre- and Post-test scores'.
GRAPH
  /SCATTERPLOT(BIVAR)=pre WITH change by grp
  /MISSING=LISTWISE
  /TITLE= 'Pre-test and change scores'.

split file separat by grp.

CORRELATIONS
  /VARIABLES=pre post change
  /PRINT=TWOTAIL NOSIG
  /MISSING=PAIRWISE .

split file off.

*  ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~ .