;/	NICKPIC by bar			/
;/	via ircnick.com			/
;/	/
;/	---				/
;/	Syntex: /nickpic <nick>		/
;/	---				/
;
;
;	ircnick.com is an archiver of data and
;	pictures from IRC, more than 10,000
;	users are signed (yah, feamles too)
;
;	%nickpic is the nick
;

alias -l nickpic.output echo $color(info) -e * /nickpic: $1-
alias -l nickpic.file return $+(%nickpic,.jpg)
alias nickpic {
  if (!$1) || ($2) { nickpic.output insufficient parameters | return }
  if ($isfile($+($1,.jpg)) == $true) .remove $+($1,.jpg)
  set %nickpic $1
  sockopen nickpic ircnick.com 80
}

ON 1:SOCKOPEN:nickpic: {
  nickpic.output Resolving picture..
  if (%nickpic.flag) unset %nickpic.flag
  window -pdoC +L @nickpic -1 -1 400 400
  titlebar @nickpic ( $+ %nickpic $+ ) ircnick.com
  sockwrite -n nickpic GET $+(/images/,%nickpic,.jpg) HTTP/1.0
  sockwrite -n nickpic Host: ircnick.com
  sockwrite nickpic $crlf
}

ON 1:SOCKREAD:nickpic: {
  if (!$window(@nickpic)) { sockclose nickpic | halt }
  if (!%nickpic.flag) { 
    sockread %temp
    if ($gettok(%temp,1,32) == Content-Length:) sockmark nickpic $gettok(%temp,2,32)
    if ($len(%temp) < 4) set %nickpic.flag .
    if ((404 isin %temp) && (found isin %temp)) || (Forbidden isin %temp) {
      sockclose nickpic
      window -c @nickpic
      nickpic.output No such nick/picture on ircnick.com
      nickpic.output Refer to 12http://www.ircnick.com/? $+ %nickpic
    }
    halt
  }
  sockread &nickpic
  bwrite $+(%nickpic,.jpg) -1 -1 &nickpic
  drawrect -fr @nickpic $rgb(1,1,$int($calc($file($nickpic.file).size * 250 / $sock(nickpic).mark))) 1 0 0 400 400
  drawtext @nickpic 15 david 20 5 5 $int($calc($file($nickpic.file).size * 100 / $sock(nickpic).mark))
}

ON 1:SOCKCLOSE:nickpic: {
  drawpic -s @nickpic 1 1 400 400 $nickpic.file
  unset %nickpic*
  .remove $nickpic.file
}