Adpwm - A/D converter and Pulse Width Modulation control

This program is based on SAD but with the addition of a pulse width modulated output on PORTB Pin0. Pulse width modulation varies the "mark space ratio" or "duty cycle" of a digital output, ie, the percentage of time that the pin is on. When repeated at a high rate, it controls the power to a pin and can be used to control the power to output devices, to dim lights and control motor speed for example.

The main program can be broken up into five main areas:

Start - This part of the program sets up the Input Output Ports. Note that all bits of Port B are set to be outputs. This is accomplished by sending the byte 00000000 (binary) to TRISB. To select TRISB, STATUS must first be set and then reset. This is because of the dual bank register system in this microprocessor. Also the routine INITAD is called which initialised the A/D converter hardware (see InitAD).
Update - This is the beginning of the main loop. The program calls the GETAD routine and then simply gets the A/D result from the register ADRES and puts it at PORTB. The sequence is then repeated.
Loop1 and Loop2 - Just before Loop1, PORTB Pin0 (the pulse width modulation output) is turned on. Then Count1 is compared with ADRES. If COUNT1>=ADRES then PORTB Pin 0 is turned off. Loop2 is just a time delay loop nested within Loop1 to slow the output down so the result can be observed on a flashing LED. The result is that a LED will change its duty cycle, according to the value detected on the A/D convertor, and the result of the A/D conversion is output to PORT B.
GetAD - This is the A/D routine. The first bit is a time delay of 10uS (3 loops) to allow the A/D converter to settle after the last conversion. Next the interrupt flag is cleared and an A/D conversion is commanded. Then ADCON0 is tested until the A/D conversion is complete.
InitAD - This part sets up the A/D hardware. First Bank1 must be selected. Then AN0 is selected as the A/D converter and VRef (5V) is used as the A/D reference voltage by programming ADCON1. Finally ADCON0 must be programmed to select AN1 and AN0 as analog inputs.


;**************************************************************************
;
;TITLE   PWM on AN2 controled by AD on channel AN1 and displayed on RB0-7
;This program is a simple implementation of the PIC16C71's A/D
;
;	  The A/D is configured as follows:
;       Vref = +5V internal.
;       A/D Osc. =  internal RC
;     
;

;**************************************************************************

#include 	"p16c711.inc"
        	LIST P=16C711

        __CONFIG _XT_OSC & _PWRTE_OFF & _WDT_OFF & _BODEN_OFF & _CP_OFF

;--------------------------------------------------------------------------
; Variables
;--------------------------------------------------------------------------

RAM	  EQU	  	0x0C
TEMP      EQU  	  	RAM+0
RESULT	  EQU	  	RAM+1
COUNT1	  EQU	  	RAM+2
COUNT2	  EQU	  	RAM+3
COUNT3	  EQU	  	RAM+4

;--------------------------------------------------------------------------
; Program Code
;--------------------------------------------------------------------------

          ORG       	0x00       
          GOTO      	Start
;
;--------------------------------------------------------------------------
; Main Program
;--------------------------------------------------------------------------

          ORG       	0x10
Start
  	  MOVLW   	B'00000000'     	;set port b as outputs
          BSF     	STATUS, RP0     
          MOVWF   	TRISB           
          BCF     	STATUS, RP0    	
  	  CALL    	INITAD
  
update	  CALL		GETAD      
	  MOVF		ADRES,W         	;get a/d value
	  MOVWF		RESULT
	  MOVWF		PORTB
	
	  BSF		PORTB,0			;turn pin on
	  CLRF		COUNT1

LOOP1	  MOVF		COUNT1,W
	  SUBWF		RESULT,W
	  BTFSS		STATUS,C		;if less than then skip
	  BCF		PORTB,0			;turn pin off
 
	  CLRF		COUNT2
LOOP2	  INCFSZ	COUNT2,F
	  GOTO 		LOOP2

	  INCFSZ	COUNT1,F
	  GOTO		LOOP1
	  GOTO		update

;
; This routine gets the result of an A->D convestion from AN1
; Result is available in ADRES;
;

GETAD	  MOVLW		D'03'		    	;setup time >= 10uS.
	  MOVWF		TEMP
SDLOOP	  DECFSZ  	TEMP, F
	  GOTO    	SDLOOP
    
	  BCF     	ADCON0,ADIF     	;clear int flag
	  BSF     	ADCON0,GO       	;start new conversion
GETADLOOP
	  BTFSC   	ADCON0,NOT_DONE 	;a/d done?
	  GOTO		GETADLOOP       	;no then keep checking
	  RETURN	                	;yes then update new value.
;
;
;InitializeAD, initializes and sets up the A/D hardware.
;

INITAD	  BSF     	STATUS,RP0      	;Configure AN1 & AN0 as input
	  MOVLW   	B'00000010'     	;Vref as Reference
	  MOVWF   	ADCON1          	;
	  BCF     	STATUS,RP0      	;
	  MOVLW   	B'11000001'     	;RC, AN0, A/D
	  MOVWF   	ADCON0          	;
	  RETURN


	  END

Contacts:

Email Peter Hayles, Author